MenuBarAppleScript - AppleScriptでメニューバーにメニュー項目とWebView付きのウインドウを作れるアプリケーション

UI Element関係

«event UIElSetE» {"AppleScript Editor", {"Attr", "AXFocusedUIElement"}}

«event UIElSetE» {"AppleScript Editor", {"Attr", "AXFocusedUIElement", "Attr1", "Value1", "Attr2", "Value2" }}

«event UIElSetE» {"AppleScript Editor", {"Attr", "AXFocusedUIElement"}, "SaveName" }

«event UIElSetE» {"AppleScript Editor", { 100, 80 } } -- 座標(x,y)で調べる(指定したアプリケーションのみ対象)

«event UIElSetE» { missing value , { 100, 80 } } -- 座標(x,y)で調べる(すべてのアプリケーションが対象)

«event UIElGetV»、«event UIElSetV»の処理対象のUI Elementを指定

値は"属性", "値" のペアを並べて書きます。対象のUI Elementの子(AXChildren)を探していきます。一番最初はAXApplicationが対象になっています。

値は文字列です。数値も文字列になります。

"値"は正規表現で書きます。部分マッチするので文字列と完全一致する場合には"^ねこ$"にします。正規表現のメタ文字も考慮して安全に書くなら"^\\Qねこ\\E$"にします。

"属性1 属性2"のように属性を半角スペースで区切って複数書くことができます。取得する値も"値1 値2"と半角スペースで区切ったものになります。

返り値は見つかったUI Elementの数です。ただし二つ以上見つかっても処理対象になるのは最初の一つです。

以下は特殊な属性値("Attr")です。

UIEl : UIElを対象とする。最初に指定可能

AXEl : AXElを対象とする。最初に指定可能

Attr : 属性を取得する。"Attr", "AXParent"で親を取得できます。

FindSelf : 通常は対象のUI Elementの子を調べますがこれを指定すると次に指定した属性と値の比較を現在のUI Elementと行います。"Attr"でUI Elementを取得して、その子ではなくそのUI Elementから探す場合に。

Index : 指定したindexの子を取得する

AnyRole : 指定したRoleの子調べて、AnyRoleの次に指定した属性と値のUI Elementが無ければ、再度AnyRoleに戻り子を探す。探しているUI ElementがどのAXScrollAreaやAXSplitGroupに入っているかわからない場合にこれを使うと探すことができます。

AnyRoleAll : 指定した子を全て調べて見つかったUI Elementを返します。AnyRoleは何か見つかった段階で終了します。

PerformAction : AXPressなどを実行できる。Setする命令だけどここに命令を追加したら楽だったので。対象のUI Elementが複数ある場合はすべてのUI Elementで命令を実行する。

上記キーで値がないものは""を指定して下さい。

実際の使い方は«event UIElSetE»のレシピ、«event UIElSetE»でGUI操作ハンドラを見て下さい。

互換性のために、一番最初に指定する属性と値は値を""にすると属性値を取得します。{"Attr", "AXFocusedUIElement" }と{"AXFocusedUIElement", "" }は同じになります。古いスクリプトでは後者のスクリプトがある場合がありますが、前者の"Attr"を使う方を推奨します。

無限ループ対策として数百回子を調べると調べるのを終了します。

値を2つの数値x,yを指定するとスクリーン上のx,y座標にあるUI Elementを対象とします。その際、アプリケーション名を指定するとそのアプリケーションのみ調べます。この時、アプリケーションが他のウインドウなどに隠れていても調べることができます。これは便利だったり不便だったりするので注意して下さい。アプリケーション名をmissing valueにすると座標にあるUI Elementをアプリケーションを限定せず取得します。

set {theRole, theVisibleCharacterRange, theValue} to «event UIElGetV» {"AXRole", "AXVisibleCharacterRange", "AXValue"}

«event UIElSetE»で指定したUI Elementの属性の値を取得。リストで指定で複数の属性を指定可能。

値が無い場合はmissing valueになります。

«event UIElSetV» {"AXVisibleCharacterRange", "pos=" & pos & " len=1"}

«event UIElSetE»で指定したUI Elementの属性の値を設定。リストで、属性、値を指定します。

UIElementInspectorで属性名の後ろに(W)と書いてあるものに、設定できます。Rangeなども取得した値の書き方でセットできます。

返り値は無く、値が設定されたかどうかは再度取得して確認する必要があります。

«event UIElSetV» {"AXSelectedTextMarkerRange", "Range", "SavedValue"}

3つ目の値を"SavedValue"にすると、値を«event UIElVal_»で保存した名前で指定できます。

«event AXElGetV» {"AXRole", "AXVisibleCharacterRange", "AXValue"}

event AXElSetV» {"AXVisibleCharacterRange", "pos=" & pos & " len=1"}

AXNotificationの通知のハンドラ実行時に通知を受けたUI Elementを対象に上と同じ処理をする命令

«event UIElIndx» { theIndex }

«event UIElIndx» { theIndex, theSaveName }

«event UIElSetE»で保存した複数のUI Elementをインデックスで切り替える

切り替えに成功すれば1、失敗すれば0を返す

theIndex : 指定するUI Elementのインデックス。«event UIElSetE»実行直後はは1。

theSaveName : どの保存したUI Elementのリストから取得するか。«event UIElSetE»で指定した名前、もしくは属性値のリスト。未指定の時は最後にUIElSetEした時のリスト。

«event UIElPAct» {"AXPress"}

«event AXElPAct» {"AXPress"}

«event UIElPAct» {"AXPress", {|modifierKeys|:"command option shift control"}}

«event AXElPAct» {"AXPress", {|modifierKeys|:"command option shift control"}}

指定した命令をPerformActionする。

二つ目の値にレコードで実行時に押す修飾キーを指定できる。

«event UIElVal_» {"Attr Name", "parameter", "SaveName"}

«event AXElVal_» {"Attr Name", "parameter", "SaveName"}

UIElの値を取得します。UIElGetVとの違いは、パラーメータを指定できる、取得した値を保存できる、です。

パラメータ("parameter")にはpositionなどを指定する場合"pos=1 len=10"のようなテキストで指定できます。

パラメータ("parameter")には"SaveName"で保存した名前を指定できます。また、"UIEl"、"AXEl"も指定できます。パラメータを空文字にするとパラーメータは指定しなくてUIElGetVと同じように値を取得します。"SaveName"で保存はできます。"SaveName"を空文字にすると値を保存しません。

例：AXWebAreaの選択しているテキストを取得する。UIElはAXWebAreaが指定されている必要があります。

«event UIElVal_» {"AXSelectedTextMarkerRange", "", "SelectedTextMarkerRange"} -- AXSelectedTextMarkerRangeをSelectedTextMarkerRangeに保存
set theSelectedText to «event UIElVal_» {"AXStringForTextMarkerRange", "SelectedTextMarkerRange", ""} -- AXStringForTextMarkerRangeを上で保存したSelectedTextMarkerRangeをパラメータにして取得

UIElementのテキストを可能な限り取得するgetUIElementTextも参考にして下さい。取得するならこれでだいたい行けると思います。

AXWebAreaで取得可能な属性@10.6.8：{"AXUIElementForTextMarker", "AXTextMarkerRangeForUIElement", "AXLineForTextMarker", "AXTextMarkerRangeForLine", "AXStringForTextMarkerRange", "AXTextMarkerForPosition", "AXBoundsForTextMarkerRange", "AXAttributedStringForTextMarkerRange", "AXTextMarkerRangeForUnorderedTextMarkers", "AXNextTextMarkerForTextMarker", "AXPreviousTextMarkerForTextMarker", "AXLeftWordTextMarkerRangeForTextMarker", "AXRightWordTextMarkerRangeForTextMarker", "AXLeftLineTextMarkerRangeForTextMarker", "AXRightLineTextMarkerRangeForTextMarker", "AXSentenceTextMarkerRangeForTextMarker", "AXParagraphTextMarkerRangeForTextMarker", "AXNextWordEndTextMarkerForTextMarker", "AXPreviousWordStartTextMarkerForTextMarker", "AXNextLineEndTextMarkerForTextMarker", "AXPreviousLineStartTextMarkerForTextMarker", "AXNextSentenceEndTextMarkerForTextMarker", "AXPreviousSentenceStartTextMarkerForTextMarker", "AXNextParagraphEndTextMarkerForTextMarker", "AXPreviousParagraphStartTextMarkerForTextMarker", "AXStyleTextMarkerRangeForTextMarker", "AXLengthForTextMarkerRange", "AXBoundsForRange", "AXStringForRange"}

AXTextArea、AXTextFieldで取得可能な属性@10.6.8：{"AXLineForIndex", "AXRangeForLine", "AXStringForRange", "AXRangeForPosition", "AXRangeForIndex", "AXBoundsForRange", "AXRTFForRange", "AXStyleRangeForIndex", "AXAttributedStringForRange"}

«event UIElPAtr»

«event UIElVal_»で指定可能なパラメータ付き属性の名前を取得します。

UIElementInspector.appでは確認できないのでこれで確認できます。

«event UIElAppI»

UIElで指定されているUIパーツを持つアプリケーション情報を取得

«event UIElAXEl»

UIElの値をAXElにする

«event UIElSave» {"name", "UIEl"/"AXEl" }

現在UIElかAXElに設定されている値を"name"に保存する

«event UIElLoad» {"name"}

«event UIElSave»で保存した値をロードする

ロードに成功したら1、失敗したら0を返す。

«event UIElFind» {"ParentAndSelf", {theAttr, theValue, theOpt}}

«event UIElFind» {"ParentAndSelf", {"AXRole", "(AXTextArea|AXTextField|AXStaticText)", "regex"}}

現在のUI Elementとその親要素から指定したtheAttrがtheValueの要素を探してUIElに設定する。

見つかれば1、見つからなければ0を返す。

theOpt : "regex" と "not"。両方指定する場合は "regex not" のようにします。

regexで比較が正規表現になります。通常は完全一致です。

notで一致しない物を探します。

AXFocusedUIElementで取得したUIElのAXScrollAreaを取得する時等に使います。

«event UIElFind» {"Parent", {theAttr, theValue, theOpt}}

"ParentAndSelf"の自分は含まないもの

HTTPサーバー機能

MenuBarAppleScriptのアプリケーションがHTTPサーバーになることができます。

何故この機能を追加したかというと、次の理由からです。

1. Macの何かのデータをiPadに表示できるかもしれない ⇒ 一個だけ自分専用のスクリプトで使いましたが、汎用的で面白いものはアイデアが思いつきませんでした…
2. UserScriptとAppleScriptの連携で、今は UserScriptからURLスキーム経由でAppleScriptを起動して、AppleScriptでブラウザのJavaScriptを実行して結果を反映させていますが、MenuBarAppleScriptがサーバーになって、AppleScriptの結果をJSONPで返してUserScriptで処理をすれば、ブラウザのAppleScriptに依存しなくて、Safari、Chrome、FirefoxどれでもUserScriptとAppleScriptの連携ができると考えたから。

«event HTTPSevr» { "start", {|Port|:21248, |DocumentRoot|:"~/Desktop", |User|:"", |Password|:""}}

«event HTTPSevr» { "stop" }

サーバーオプション

Port : ポート番号

DocumentRoot : ここで指定したフォルダを起点にファイルを探す

DirectoryIndexFileNames : DocumentRoot内のフォルダにアクセス時に表示するファイル
例：{"index.html", "index.htm"}

User, Password : ログインに必要なユーザー名とパスワード。""もしくはmissing valueでログイン無しでアクセス可能。パスワードのみ指定可能。

返り値：

1 : サーバ起動OK

1以外 : エラー内容の文字列

theThisAppRecordのHTTPServerURLにサーバのURL、HTTPServerPortにポートのみ、HTTPServerStatusにサーバの状態が入ります。0:未起動、1:起動OK、文字列:起動時のエラーメッセージ

サーバーのレスポンスの処理はon doHTTPResponse(theRequestPath, theDocumentFilePath, theMethod, theActiveAppRecord, theThisAppRecord)で行います。

theRequestPath : リクエストのパス。

theDocumentFilePath : リクエストのパスをDocumentRootフォルダのパスに変換したもの。フォルダの場合、末尾に/が付きます。

theMethod : "GET", "HEAD" など

theRequestPathはparseURLで調べることができます。

JSONPを返す場合はwriteJSONでレコードからJSONを作ることができます。

バグ : 大きなファイルを返したり、doHTTPResponseのAppleScriptの処理に時間がかかる場合、MenuBarAppleScriptのアプリケーションが落ちる場合があります。

サンプル：doHTTPResponseの使用例

Dictionary Services (辞書サービス)

Dictionary Services Referenceの命令です。

ハッシュではないです。

«event DicSShow» { theText, theTextOffset, { theShowWindowX, theShowWindowY } }

«event DicSShow» { theText, theTextOffset, { theShowWindowX, theShowWindowY }, theSavedAttributedStringName }

«event DicSShow» { "りんご", 1, { 20, 20 } }

辞書をポップアップウインドウで表示

theTextOffset : 単語の位置。1ベースのインデックスで指定。。missing valueを指定すると、指定したテキストをそのまま調べます。

単語は文字列中の位置で指定します。theTextをそのまま調べたい場合はtheTextOffsetをmissing valueにします。

{ theShowWindowX, theShowWindowY }はディスプレイの左上が{ 0 , 0 }の座標。

theSaveAttributedStringNameは«event UIElVal_»で保存したAttributedStringを指定する場合。

HIDictionaryWindowShow

«event DicSTerm» { theText, theTextOffset }

«event DicSTerm» {"海外旅行に行ってきたよ！", 1 }

theTextのtheTextOffsetの位置の単語と単語のRangeを返します。無ければ{ missing value, missing value }を返す。

例：{"海外旅行", "pos=0 len=4"}

theTextOffset : 単語の位置。1ベースのインデックス。

単語は文字列中の位置で指定します。単語だけならtheTextOffsetを1にして、theTextに表示したい単語を指定します。

"TextOffset"のようにくっついている文字列でも、"Text"や"Offset"を取得できます。日本語も"海外旅行に行く"の場合、"海外旅行"や"行く"を取得できます。

DCSGetTermRangeInString

«event DicSDef_» { theText, theTextOffset, theDictName }

«event DicSDef_» {"海外", 1, "国語辞典"}

«event DicSDef_» {"apple", 1, "英和／和英辞典"}

«event DicSDef_» {"りんご", 1, "英和／和英辞典"}

«event DicSDef_» {"感じ", 1, "類語辞典"}

«event DicSDef_» {"Finder", 1, "Apple"}

«event DicSDef_» {"犬", 1, "Wikipedia"}

theTextのtheTextOffsetの位置の単語の意味を返します。無けれればmissing value

theTextOffset : 単語の位置。1ベースのインデックス。missing valueを指定すると、指定したテキストをそのまま調べます。

theDictName : 辞書名。辞書.appの環境設定で確認できます。未指定もしくは無い場合はデフォルトの辞書で調べます。

単語は文字列中の位置で指定します。単語だけならtheTextOffsetを1にして、theTextに表示したい単語を指定します。

DCSCopyTextDefinition

テキスト 一般

詳しい説明はNSString Class Referenceを見て下さい。

«event TextUtil» {"lowercaseString", theText}

小文字にする

«event TextUtil» {"uppercaseString", theText}

大文字にする

«event TextUtil» {"capitalizedString", theText}

Abcのようにする

«event TextUtil» {"capitalizedString", theText}

Abcのようにする

«event TextUtil» {"printfInt", "%04d", 12}

printfで数値を整形する。値は一つだけなので%dは一つだけで、指定する数値も一つです。

«event TextUtil» {"printfFloat", "%.2f", 12.345678}

printfでfloat値を整形する。値は一つだけなので%fは一つだけで、指定する数値も一つです。

«event TextUtil» {"strtol", theText, theBase}

«event TextUtil» {"strtol", theText, { theBase1, theBase2, theBase3 } }

«event TextUtil» {"strtol", "AA", 16}

«event TextUtil» {"strtol", "AA 99 FF", { 16, 16, 16 } }

strtolでテキストを数値に変換します。

変換でエラーになった場合はmissing valueを返します。

theBaseをリストで複数渡すことができます。その場合の返り値は数値のリストになります。変換でエラーになった場合はリストのそのエラーに成った値からmissing valueになります。

実際には大きな数値でもいいようにstrtollを呼び出して変換しています。

«event TextUtil» {"parseJSON", theURLorText}

JSONのURL又はJSONのテキストを渡して、JSONのレコードを返す

parseに失敗した場合はmissing valueを返します

«event TextUtil» {"parseXML", theURLorText}

XMLのURL又はXMLのテキストを渡すしてそのXMLのレコードを返す

parseに失敗した場合はmissing valueを返します

参考：Simple XML to NSDictionary Converter

«event TextUtil» {"writeJSON", theRecord }

レコードをJSONのテキストに変換する

«event TextUtil» {"MGTemplateEngine", theTemplate, theValueRecord }

«event TextUtil» {"MGTemplateEngine", theTemplate, theValueRecord, thePersistentValueRecord }

«event TextUtil» {"MGTemplateEngine", theTemplate, theValueRecord, thePersistentValueRecord, {|OpenHTML|:1, |Browser|:"Safari", |OpenText|:0, |Editor|:"mi", |Activate|:0, |Name|:"UseCount"} }

MGTemplateEngineを使用する

theTemplate : テンプレートファイルのパス、もしくはテンプレートのテキスト

theValueRecord : テンプレートの値のレコード

thePersistentValueRecord : テンプレートの値のレコードその2。固定値をこのレコードに入れておくに感じでしょうか。

{|OpenHTML|:1, |Browser|:"Safari", |OpenText|:0, |Editor|:"mi", |Activate|:0, |Name|:"UseCount"} : テンプレートの結果をブラウザやテキストエディタで開く場合の設定

・フィルタ

uppercase

lowercase

capitalized

・MenuBarAppleScriptの追加フィルタ

html : テキストにhtmlspecialcharsを適用する。HTMLで表示するテキストの場合に使用

decodehtml : テキストにdecodeHtmlSpecialcharsを適用する。

encode : テキストにencodeURIComponentを適用する。

decode : テキストにdecodeURIComponentを適用する。

・テンプレート書き方

{% literal %}This text won't be {% now %} interpreted.{% /literal %}

{{ key }}

{{ key | html }}

{{ key | encode }}

{{ users.@count }}

{{ users.@lastObject }}

{% cycle a b c %} {{ value }} {% /cyble %}

{{ currentLoop.currentIndex }} {{ currentLoop.startIndex }} {{ currentLoop.endIndex }} {{ currentLoop.reversed }}

{{ currentLoop.parentLoop.currentIndex }} {{ currentLoop.parentLoop.startIndex }} {{ currentLoop.parentLoop.endIndex }} {{ currentLoop.parentLoop.reversed }}

{% for 1 to 5 %} {{ currentLoop.currentIndex }} {% /for %}

{% for 1 to 5 reversed %} {{ currentLoop.currentIndex }} {% /for %}

{% for path in paths %} {{ path }} {% /for %}

{% for path in paths reversed %} {{ currentLoop.currentIndex }} {{ path }} {% /for %}

{% for user in users %} {{ currentLoop.currentIndex }} {{ user.name }} {{ user.age }} {% /for %}

{% for user in users reversed %} {{ currentLoop.currentIndex }} {{ user.name }} {{ user.age }} {% /for %}

{%if item.usedcount >= hilightUsedCount %} TRUE {%/if%}

{%if item.usedcount >= hilightUsedCount %} TRUE {%else%} FALSE {%/if%}

{% if 'text1' equalsstring 'text1' %} same {% /if %}

{% if 'text1' notequalsstring 'text2' %} not same {% /if %}

{%if currentLoop.currentIndex % 2 %}odd{%else%}even{%/if%}

ifで使える演算子一覧 : and , %% , or , || , = , == , != ,<> , > , < , >= , <= , % , equalsstring , notequalsstring

メモ：上記演算子のandを使ってみたら使い方が悪いのか動きませんでした。ifを二重にしました。

{% cycle odd even %}

{% cycle 'odd a' 'even b' %}

・http://mattgemmell.com/files/sample_template.txt

・MGTemplateEngineのテンプレート例

テキスト URL関係

«event TextURL_» {"encodeURIComponent", theText [, mojiCode] }

encodeURIComponentする

mojiCodeは"UTF8","SJIS","EUC-JP"。"JIS"はエラーになります

«event TextURL_» {"decodeURIComponent", theText [, mojiCode] }

decodeURIComponentする

mojiCodeは"UTF8","SJIS","EUC-JP"。"JIS"はエラーになります

«event TextURL_» {"parseURL", theURL }

URLの属性のレコードを返します。特に使えそうなのはqueryをrecordにした|queryRecord|です。

レコードのキーは次の通りです。

|queryRecord|
|absoluteString|
|absoluteURL|
|baseURL|
|fragment|
|host|
|lastPathComponent|
|parameterString|
|password|
|path|
|pathComponents|
|pathExtension|
|port|
|query|
|relativePath|
|relativeString|
|resourceSpecifier|
|scheme|
|user|

AppleScriptEditorHelperで上記キーを挿入することができます。

Googleのqを取得するには次のようにします。qは複数回設定され場合もあるのでリストになるのでitem 1で指定します。

	set theURLRecord to «event TextURL_» {"parseURL", "http://www.google.co.jp/search?q=3ds"}
	«event DebugLog» (theURLRecord)
	«event DebugLog» (item 1 of q of |queryRecord| of theURLRecord)

«event TextURL_» {"htmlspecialchars", theText }

&, <, >, ", 'を&amp;などに置換する

«event TextURL_» {"decodeHtmlSpecialchars", theText }

htmlspecialcharsの逆の処理。

テキスト 正規表現関係(RE)

• RegexKitLite - ICUSyntax：これを使っています。
• 正規表現メモ

TextRegxは引数の順番がイマイチで気になるのでそれを直した新しい命令を作りました。

«event TextRE__» {"isMatched", "text", "pattern" }

パターンにマッチするなら1

«event TextRE__» {"capture", "abc 123 efg", "([0-9]+)", 1 }

«event TextRE__» {"capture", "abc 123 efg", "(\\w+) ([0-9]+)", {1,2} }

パターンの()で囲った物を取得する。()は1からの番号で指定する

リストで複数指定可能。返り値はリストになります。

«event TextRE__» {"matchedList", "123 abc 456 efg", "[0-9]+" }

結果：{ "123", "456" }

パターンにあう文字列をすべて抜き出しリストで返す

matchedListは()で囲った物を返すのではなくて、パターンにあう物を返す。特定の文字に囲まれた部分を取得するには次のようにする

例:hrefの値を取得：«event TextRE__» {"matchedList", theHTML, "(?<=<a href=\")(.*?)(?=\">)" }

«event TextRE__» {"split", "text", "pattern" }

パターンでテキストを分割してリストで返す

«event TextRE__» {"replace", "text", "pattern", "replaceText" }

パターンを"replaceText"で置換する

テキスト 正規表現関係

• RegexKitLite - ICUSyntax：これを使っています。
• 正規表現メモ

«event TextRegx» {"isMatched", "pattern", "text" }

パターンにマッチするなら1

«event TextRegx» {"capture", "([0-9]+)", "abc 123 efg", 1 }

«event TextRegx» {"capture", "(\\w+) ([0-9]+)", "abc 123 efg", {1,2} }

パターンの()で囲った物を取得する。()は1からの番号で指定する

リストで複数指定可能。返り値はリストになります。

«event TextRegx» {"matchedList", "[0-9]+", "123 abc 456 efg" }

結果：{ "123", "456" }

パターンにあう文字列をすべて抜き出しリストで返す

matchedListは()で囲った物を返すのではなくて、パターンにあう物を返す。特定の文字に囲まれた部分を取得するには次のようにする

例:hrefの値を取得：«event TextRegx» {"matchedList", "(?<=<a href=\")(.*?)(?=\">)", theHTML }

«event TextRegx» {"split", "pattern", "text" }

パターンでテキストを分割してリストで返す

«event TextRegx» {"replace", "pattern", "text", "replaceText" }

パターンを"replaceText"で置換する

テキスト パス関係

詳しい説明はNSString Class Referenceを見て下さい。

Finderでできるのに何故あるのかというとFinderでファイル操作をしているとエラーになることがたまにあってFinderを信用してないからです。

コマンドでもできますが、命令を用意したほうが処理が軽いかなと思い（未確認）機能を付けました。

«event TextPath» {"url", thePath}

thePathのURLを返す

«event TextPath» {"exists", thePath}

ファイルが存在すれば1、無ければ0

«event TextPath» {"isDirectory", thePath}

フォルダなら1、ファイルなら0

«event TextPath» {"stringByExpandingTildeInPath", thePath}

~/hogeのパスをフルパスに展開する

«event TextPath» {"lastPathComponent", thePath}

パスの最後の要素名(ファイル名、フォルダ名)を返す

«event TextPath» {"pathExtension", thePath}

拡張子を返す

«event TextPath» {"stringByDeletingLastPathComponent", thePath}

パスの最後の要素を削除したパスを返す

«event TextPath» {"stringByDeletingPathExtension", thePath}

拡張子を削除したパスを返す

«event TextPath» {"stringByAbbreviatingWithTildeInPath", thePath}

/Users/hoge/foo/a.txtを~/foo/a.txtにする。ユーザーが存在しない場合はそのままのパスを返す

«event TextPath» {"stringByAppendingPathComponent", thePath, "inu.zip"}

指定した値をパスに追加する

«event TextPath» {"stringsByAppendingPaths", thePath, {"mac", "wii"}}

指定したパスにリストで指定した値を追加したパスをリストで返す

«event TextPath» {"isAbsolutePath", thePath}

絶対パスなら1

«event TextPath» {"stringByResolvingSymlinksInPath", thePath}

シンボリックリンクの元パスを返す

«event TextPath» {"stringByStandardizingPath", thePath}

/hoge//hage/a.jpgの//を/に戻す等して通常のパスにしたものを返す

«event TextPath» {"move", theSrcPath, theDstPath }

ファイルを移動する

成功したら1を返す。

«event TextPath» {"copy", theSrcPath, theDstPath }

ファイルをコピーする

成功したら1を返す。

«event TextPath» {"remove", thePath}

ファイルを削除する

成功したら1を返す。

«event TextPath» {"createDirectory", thePath}

フォルダを作成する

成功したら1を返す。

«event TextPath» {"contentsOfDirectory", thePath }

«event TextPath» {"contentsOfDirectory", thePath, { "SkipsHiddenFiles", "folderOnly", "fileOnly", "AddSlashToFolder" } }

フォルダ内のファイルを取得する

SkipsHiddenFiles : 不可視ファイルは取得しない

folderOnly : フォルダのみ取得する

fileOnly : ファイルのみ取得する

AddSlashToFolder : フォルダ名の末尾に/を追加する

«event TextPath» {"moveToTrash", thePath}

ファイルをゴミ箱に移動する

返り値は無し

«event TextPath» {"duplicate", thePath}

ファイルを複製する

Finderで複製するのと同じ

返り値は無し

«event TextPath» {"setIcon", thePath, theImagePathOrURL }

アイコンを設定する

成功したら1を返す。

«event TextPath» {"getTag", thePath }

10.9のタグを取得する

成功したらタグをリストで返します。

無い場合は空のリストを返します。

失敗したらmissing valueを返します

«event TextPath» {"setTag", thePath, theTagStrOrTagList }

10.9のタグをファイルに設定する

成功したら1を返す。

既存のタグを全て消して設定したタグになります。追加したい場合はaddTagを使います。

theTagStrOrTagListは下記のように指定できるということです。

«event TextPath» {"setTag", thePath, "Apple" }

«event TextPath» {"setTag", thePath, { "Apple", "Store" } }

«event TextPath» {"addTag", thePath, theTagStrOrTagList }

10.9のタグをファイルに追加する

成功したら1を返す。

localizedCaseInsensitiveCompareで同じタグがあるかどうか調べ、すでにあれば追加しません

localizedCaseInsensitiveCompareは全角、半角とひらがな、カタカナを同じとして比較します。

«event TextPath» {"removeTag", thePath, theTagStrOrTagList }

10.9のタグをファイルから取り除く

localizedCaseInsensitiveCompareで同じタグかどうか比較します。

localizedCaseInsensitiveCompareは全角、半角とひらがな、カタカナを同じとして比較します。

成功したら取り除いたタグの数を返す。

日付関係

«event DateUtil» {"SecondsUntilDate", {|Year|:2101, |Month|:1, |Day|:1, |Hour|:0, |Minute|:0, |Second|:0}}

«event DateUtil» {"SecondsUntilDate", {|Month|:1, |Day|:1, |Hour|:0, |Minute|:0, |Second|:0}}

«event DateUtil» {"SecondsUntilDate", {|Day|:2, |Hour|:2, |Minute|:2, |Second|:2}}

«event DateUtil» {"SecondsUntilDate", {|Hour|:23, |Minute|:0, |Second|:0}}

«event DateUtil» {"SecondsUntilDate", {|Minute|:30, |Second|:0}}

«event DateUtil» {"SecondsUntilDate", {|Second|:30}}

«event DateUtil» {"SecondsUntilDate", "2013-04-12 15:30:45 +0900"}

指定した時間までの秒数を返す。

DoAtTimeで指定する時間と同じレコードです。何秒後にDoAtTimeのハンドラが実行されるのか確認したい場合などに

辞書(ハッシュ)関係

Cocoaで辞書、一般にはハッシュと呼ばれる、文字列をキーとして、データを参照する機能を実現する命令です。

あったら便利だと思うので付けてみました。

これを使う利点は辞書が便利だから以外に、ここに保存したデータはMenuBarAppleScriptのスクリプトを変更、保存してもMenuBarAppleScriptのアプリケーションが起動している限り保持されるので、ここに状態を保存すると、スクリプトを保存、更新しても、次の実行時に前回の状態のままスクリプトを実行できます。開発中のアプリケーションでスクリプトの一部分を変更した場合でも、propertyに保存するとスクリプトを保存した時に初期化されてしまいますが、これを使うと前回の状態を保持したまま実行できます。

また、return {|SaveDict|:1}を返すと、辞書の値をPreferenceのplistに保存するようになり、アプリケーションを終了、再起動しても値を保持できるようになります。デフォルト値も1です。なお、値の読み込みは起動時に自動的に行われます。

辞書のキーには文字列以外も指定できますが内部で文字列に変換されます。これはplistでは辞書のキーは文字列のみ有効だからです。その為、"1"と1は同じキーとなるので注意してください。

dictNameが次のものは保存前に削除します

実行中のみの一時データは下記名前にすると保存ません。

"^(?i)te?mp([-_ ]|$)"

上記正規表現にマッチする名前の辞書を削除します。

例：すべて大文字小文字は区別しません

"tmp"

"temp"

"tmp-"から始まるもの

"tmp_"から始まるもの

"tmp "から始まるもの

"temp-"から始まるもの

"temp_"から始まるもの

"temp "から始まるもの

«event DictSetV» {dictName, "theKey", "value" }

«event DictSetV» {dictName, "theKey", {"hoge", "hage" } }

dictNameという名前の辞書の"theKey"の値をリスト"value"、{"hoge", "hage" }に設定。

設定できる値は、文字列、数値、リスト、レコードです。date型やアプリケーション独自の値は設定できません。

内部ではリストは配列(NSArray)、レコードは辞書(NSDictionary)になります。

dictName[theKey] = theValue;

«event DictSetD» {dictName, "theKey", "defaultValue" }

値の初期値を設定します。

«event DictGetV»をした時に、«event DictSetV»で値を設定していない場合にmissing valueでなく、これで設定した値を返します。

主に、アプリケーションの初期設定を指定するのに使います。

«event DictGetV» {dictName, "theKey"}

«event DictGetV» {dictName, "theKey", theDefaultValue }

dictNameという名前の辞書の"theKey"の値を取得

値が未設定の場合、missing valueを返します。メモ：missing valueはFourCC "msng"でした。

"DefaultValue"を指定すると値が未設定の場合、theDefaultValueを返します。値が設定されていないなら初期値を設定して実行する場合、ここで初期値を指定しておくと、ifで調べる必要が無くなります。

«event DictGetL» {dictName, "theKey"}

dictNameという名前の辞書の"theKey"の値を取得

値が未設定の場合、空のリストを返します。

リストを設定、取得する場合で、空のリストを初期値としていい場合、これを使うと、リストの値をすでに設定してあるか調べる必要がありません。

«event DictNotV» {dictName, "theKey"}

«event DictNotV» {dictName, "theKey", theDefaultValue }

値が0以外の数値の場合0に、0の場合1にして、その値を返します。

値が数値以外の場合は何もしません。

主に設定のオンオフをトグルするのに使います。

«event DictDelV» {dictName, "theKey"}

dictNameという名前の辞書の"theKey"のキーと値を削除

«event DictDelA» {dictName}

dictNameという名前の辞書のすべてのキーと値を削除

«event DictAKey» {dictName,"sort function"}

dictNameという名前の辞書のすべてのキーをリストで返す

"sort function"は次のものがあります。未指定でソートしません。

compare

caseInsensitiveCompare

localizedCaseInsensitiveCompare

localizedStandardCompare

«event DictAVal» {dictName,"sort function"}

dictNameという名前の辞書のすべての値をリストで返す

"sort function"は次のものがあります。未指定でソートしません。

compare

caseInsensitiveCompare

localizedCaseInsensitiveCompare

localizedStandardCompare

«event DictInit»

すべての辞書を削除する

«event DictList» {dictName,"listKey",actionName, "value1"}

辞書 dictName の"listKey"の値がリストの場合、actionNameの処理を実行する

«event DictList»の命令

«event DictList»の命令

リスト操作であれば便利そうなのを入れてみました。

この命令は対象のリストを変更します。

値を取得する物で、値を取得できなかった場合はmissing valueを返します。

直接リストを操作したい場合は下記のように«event HndlList»にして、theListで直接リストを指定します。命令の種類は下記«event DictList»と同じです。

返り値のtheListが処理済みのリストで、theResultは処理した時の値で無い場合はmissing valueになります。shiftやpopの場合等に値が入っています。

set {theList, theResult} to «event HndlList» {theList,"sort", "localizedStandardCompare" }

«event DictList» {dictName,listKey,"objectAtIndex", 1}

指定したindexの値を取得。indexはAppleScriptのリストと同じ1からカウントします。

«event DictList» {dictName,listKey,"indexOfObject", "hoge"}

指定した値のindexを取得。indexはAppleScriptのリストと同じ1からカウントします。見つからない場合は-1になります。

«event DictList» {dictName,listKey,"containsObject", "hoge"}

指定した値が含まれるなら1。無いなら0

«event DictList» {dictName,listKey,"count"}

要素の数を返す

«event DictList» {dictName,listKey,"reverse"}

順番を逆にする

«event DictList» {dictName,listKey,"pop"}

最後の要素を返して、最後の要素はリストから削除する

«event DictList» {dictName,listKey,"shift"}

最初の要素を返して、最初の要素はリストから削除する

«event DictList» {dictName,listKey,"addObject", "hoge"}

«event DictList» {dictName,listKey,"push", "hoge"}

値を最後に追加する

«event DictList» {dictName,listKey,"unshift", "hoge"}

値を先頭に追加する

«event DictList» {dictName,listKey,"addObjectsFromArray", { "hoge", "hage" } }

指定したリストの要素をリストに追加する

«event DictList» {dictName,listKey,"setArray", { "hoge", "hage" } }

リストの内容をを指定したリストの内容にする

«event DictList» {dictName,listKey,"trim", 10}

リストの要素数が指定した数値以上の場合、後ろから削除して指定した要素数にする。少ない場合は何もしない。

«event DictList» {dictName,listKey,"head", 10}

リストの最初から10個の要素を取り出す。少ない場合は無いにもしない。trimと同じ

«event DictList» {dictName,listKey,"tail", 10}

リストの後ろから10個の要素を取り出す。少ない場合は何もしない。

«event DictList» {dictName,listKey,"removeLastObject"}

最後の要素を削除する。リストが空の場合は何もしない

«event DictList» {dictName,listKey,"removeAllObjects"}

すべての要素を削除する

«event DictList» {dictName,listKey,"removeObject", "hoge"}

指定した要素を削除する。無い場合は何もしない。複数ある場合はすべて削除される。

«event DictList» {dictName,listKey,"removeObjectsInArray", { "hoge", "hage" } }

指定したリストに入っている要素を削除する。無い場合は何もしない。

«event DictList» {dictName,listKey,"sort", "sort function" }

リストをソートする

"sort function"は次のものがあります

compare

caseInsensitiveCompare

localizedCaseInsensitiveCompare

localizedStandardCompare

«event DictList» {dictName,listKey,"isEqualToArray", theList }

指定したリストと同じなら1

«event DictList» {dictName,listKey,"uniq"}

重複している要素を削除

«event DictList» {dictName,listKey,"grep", "pattern" }

指定した正規表現にマッチする物だけのリストにする

«event DictList» {dictName,listKey,"notgrep", "pattern" }

指定した正規表現にマッチしない物だけのリストにする

«event DictList» {dictName,listKey,"insertAfterEveryItem", "hoge" }

{1,2,3}が{1,"hoge",2,"hoge",3,"hoge"}になります。

«event DictList» {dictName,listKey,"insertBeforeEveryItem", "hoge" }

{1,2,3}が{"hoge",1,"hoge",2,"hoge",3}になります。

«event DictList» {dictName,listKey,"insertAfterTheItem", "find", "insert" }

{1,"find",3}が{1,"find","insert",3}になります。

挿入した項目数を返します

MenuItemListの特定のメニュー項目に属性を追加するのに使えます。

«event DictList» {dictName,listKey,"insertBeforeTheItem", "find", "insert" }

{1,"find",3}が{1,"insert","find",3}になります。

挿入した項目数を返します

«event DictList» {dictName,listKey,"insertListAfterEveryItem", theInserList }

«event DictList» {dictName,listKey,"insertListAfterEveryItem", {8,9} }

リストを展開して追加します

{1,2,3}が{1,8,9,2,8,9,3,8,9}になります。

«event DictList» {dictName,listKey,"insertListBeforeEveryItem", theInserList }

«event DictList» {dictName,listKey,"insertListBeforeEveryItem", {8,9} }

リストを展開して追加します

{1,2,3}が{8,9,1,8,9,2,8,9,3}になります。

«event DictList» {dictName,listKey,"insertListAfterTheItem", "find", theInserList }

«event DictList» {dictName,listKey,"insertListAfterTheItem", "find", {8,9} }

{1,"find",3}が{1,"find",8,9,3}になります。

リストを展開して追加します

挿入した項目数を返します

MenuItemListの特定のメニュー項目に属性を追加するのに使えます。

«event DictList» {dictName,listKey,"insertListBeforeTheItem", "find", theInserList }

«event DictList» {dictName,listKey,"insertListBeforeTheItem", "find", {8,9} }

{1,"find",3}が{1,8,9,"find",3}になります。

リストを展開して追加します

挿入した項目数を返します

«event DictList» {dictName,listKey,"prependTextToEveryItem", "hoge" }

すべての要素のテキストの前に指定したテキストを追加します。

{"a","b"}が{"hogea","hogeb"}になります。

«event DictList» {dictName,listKey,"appendTextToEveryItem", "hoge" }

すべての要素のテキストの後ろに指定したテキストを追加します。

{"a","b"}が{"ahoge","bhoge"}になります。

«event DictList» {dictName,listKey,"replaceTextToEveryItem", "pattern", "replaceText" }

すべての要素のテキストの指定した正規表現パターンにマッチする物を"replaceText"で置換します。

正規表現なので気をつけて下さい。

«event DictList» {dictName,listKey,"join", "text"}

リストを"text"で結合した文字列を返す

«event DictDict»の命令

辞書(レコード)操作であれば便利そうなのを入れてみました。

値を取得する物で、値を取得できなかった場合はmissing valueを返します。

直接レコードを操作したい場合は下記のように«event HndlDict»にして、theRecordで直接リストを指定します。命令は下記«event DictDict»と同じです。

返り値のtheRecordが処理済みのレコードで、theResultは処理した時の値で無い場合はmissing valueになります。

set {theRecord, theResult} to «event HndlDict» {theRecord,"setObjectForKey", theObject, theKey }

«event DictDict» {dictName,dictKey,"objectforkey", theKey }

theKeyの値を取得。無ければmissing value

«event DictDict» {dictName,dictKey,"setObjectForKey", theObject, theKey }

theKeyをtheObjectにする

«event DictDict» {dictName,dictKey,"removeObjectForKey", theKey }

theKeyの値を削除する

«event DictDict» {dictName,dictKey,"count" }

値の数を返す

«event DictDict» {dictName,dictKey,"removeAllObjects" }

すべての値を削除する

«event DictDict» {dictName,dictKey,"removeObjectsForKeys", { key1, key2 } }

指定したキーのリストの値を削除する

«event DictDict» {dictName,dictKey,"allKeys", "sort function" }

すべてのキーをリストで返す

"sort function"は次のものがあります。未指定でソートしません。

compare

caseInsensitiveCompare

localizedCaseInsensitiveCompare

localizedStandardCompare

«event DictDict» {dictName,dictKey,"allValues", "sort function" }

すべての値をリストで返す

"sort function"は次のものがあります。未指定でソートしません。

compare

caseInsensitiveCompare

localizedCaseInsensitiveCompare

localizedStandardCompare

«event DictDict» {dictName,dictKey,"isEqualToDictionary", theRecord }

指定したレコードと同じなら1

«event DictDict» {dictName,dictKey,"setDictionary", theRecord }

辞書を設定する

«event DictDict» {dictName,dictKey,"allKeysForObject", theObj }

値がtheObjのキーをリストで返す

«event DictNum_»の命令

辞書の指定したキーに値が無い場合は0を処理対象にする

«event DictNum_» {dictName,dictKey,"+", 1}

数値を足して、足した後の数を返す

- * /も使用できます。

«event DictNum_» {dictName,dictKey,"not"}

値が0かmissing valueなら1を、それ以外なら0を返す

«event DictText»の命令

辞書の指定したキーに値が無い場合は空文字列を処理対象にする

«event DictText» {dictName,dictKey,"append", "abc"}

テキストを末尾に追加して、追加後のテキストを返す

«event DictText» {dictName,dictKey,"compare", "abc", "compare"/"caseInsensitiveCompare"/"localizedCaseInsensitiveCompare"/"localizedStandardCompare"}

テキストを比較して結果を返す。結果は-1,0,1の数値。辞書文字列が大きい場合1。

最後の値は比較関数

URLスキーム

初期設定でURLスキームを設定するとそのURLを開いた時に下記ハンドラが実行されます。

on doOpenURL(theURL, theActiveAppRecord, theThisAppRecord)

URLの分析するにはparseURLを使うと便利かもしれません。

他のアプリケーションからURLを開くと、MenuBarAppleScriptアプリケーションがアクティブになり、現在アクティブなアプリケーションがアクティブじゃなくなります。バックグラウンドで、URLを使って命令をやり取りする場合には、結構気になります。それを回避するには、初期設定のアプリケーションの実行タイプをLSBackgroundOnlyにします。ただし、デフォルトのLSUIElementとGUIを利用する場合の細かい動作が違ってきます。

アプリケーション実行タイプ別特徴

通常

Dockに表示される普通のアプリケーション

doQuitの処理が確実にすべて実行される

LSUIElement

Dockに表示されないアプリケーション

サービスを実行した時はアクティブになる

doQuitで時間がかかる処理をしたら処理中でもアプリケーションが強制終了する

LSBackgroundOnly

Dockに表示されないアプリケーション

サービスを実行した時もアクティブにならない

Cmd + Cでテキストを選択できない

doQuitで時間がかかる処理をしたら処理中でもアプリケーションが強制終了する

起動直後のイベントの実行順書

1. doInit
2. doRun
3. doService系、doOpenFile、doOpenURL
4. 上のがなければ、doRunWithNoServiceNoOpenFileNoOpenURL

UIElementInspector

UI ElementはUIElementInspectorで調べることができます。「Download Sample Code」をダウンロードするとアプリケーションが入っています。

属性名の最後に(W)と書いてある物が設定可能になります。Position、Rangeなどを設定するには取得した属性と同じ形式のテキストを作成して渡すことにより設定可能です。

値によってはGUI Scriptingでは取得、設定できない物もありますので、いろいろ楽しめるのではないかと思います。

スクリプトレシピ

基本テンプレート

スクリプト

property theMenuBarItemImage : "icon Finder" --  -- メニューバーの画像。無い場合はmissing value
property theMenuBarTitle : "タイトル" -- メニューバーのタイトル 。無い場合はmissing value
property theMenuItemList : {"メニュー1", "メニュー2"}

on run
	-- デバッグ用
	-- tellするアプリケーションを編集中のMenuBarAppleScriptアプリケーションにしておく必要があります
	
	-- ハンドラをテスト実行
	-- theActiveAppRecord は «event InfoAApp»
	-- theThisAppRecord は «event InfoTApp» 
	-- になります
	my doSelectMenuItem("メニュー1", 1, «event InfoAApp», «event InfoTApp»)
end run

on doInit(theActiveAppRecord, theThisAppRecord)
	return {|SaveDict|:1, |LogAppleScriptError|:1, |DebugLog|:1, |DebugJavaScript|:0, |AutoAddQuitMenuItem|:1, |AutoAddLaunchOnLoginMenuItem|:1, |AutoAddVersionMenuItem|:1, |AutoSaveAndRestoreWindowFrameByName|:1, |MenuBarItemImage|:theMenuBarItemImage, |MenuBarItemTitle|:theMenuBarTitle, |MenuItemList|:my getMenuItemList(theActiveAppRecord, theThisAppRecord)}
end doInit

on doRun(theActiveAppRecord, theThisAppRecord)
	-- 起動直後に処理をするならここに記述
end doRun

on getMenuItemList(theActiveAppRecord, theThisAppRecord)
	set theWorkList to theMenuItemList
	
	-- ここでメニューアイテムにチェックを付けたりする

	set end of theWorkList to (current date) as text
	
	set theWorkList to {|name| of theThisAppRecord, "---separatorItem"} & theMenuItemList
	
	return theWorkList
end getMenuItemList

on setMenuItem(theActiveAppRecord, theThisAppRecord)
	«event MBASHndl» {|MenuItemList|:my getMenuItemList(theActiveAppRecord, theThisAppRecord)}
end setMenuItem

on doSelectMenuItem(theTitle, theTag, theActiveAppRecord, theThisAppRecord)
	-- メニュー選択時の処理
	if theTitle is "メニュー1" then
		beep
	end if
end doSelectMenuItem

サービス用アプリケーションテンプレート

サービスから実行するアプリケーションのテンプレートです。テキストとファイル、ついでにURLが書いてありますが、必要無いものは消して下さい。

on run
	-- デバッグ用
	-- tellするアプリケーションを編集中のMenuBarAppleScriptアプリケーションにしておく必要があります
	my doTextService("テキスト text TEXT", «event InfoAApp», «event InfoTApp»)
	my doFileService({"/hoge.txt"}, «event InfoAApp», «event InfoTApp»)
	my doOpenURL("http://memogakisouko.appspot.com/MenuBarAppleScript.html#download", «event InfoAApp», «event InfoTApp»)
end run

on doInit(theActiveAppRecord, theThisAppRecord)
	return {|LogAppleScriptError|:1, |DebugLog|:1, |SaveDict|:1}
end doInit

on doTextService(theText, theActiveAppRecord, theThisAppRecord)
	«event DebugLog» theText
	-- 処理をする
	set theText to «event TextUtil» {"lowercaseString", theText}
	-- 置換する場合ReplaceStringを返す
	return {|ReplaceString|:theText, |QuitAfterSec|:30.0}
end doTextService

on doFileService(thePathList, theActiveAppRecord, theThisAppRecord)
	«event DebugLog» thePathList
	repeat with thePath in thePathList
		-- thePath に処理をする
	end repeat
	
	return {|QuitAfterSec|:30.0}
end doFileService

on doOpenFile(thePathList, theActiveAppRecord, theThisAppRecord)
	my doFileService(thePathList, theActiveAppRecord, theThisAppRecord)
end doOpenFile

on doOpenURL(theURL, theActiveAppRecord, theThisAppRecord)
	set theURLRecord to «event TextURL_» {"parseURL", theURL}
	«event DebugLog» theURLRecord
	-- URLの処理をする
	
	return {|QuitAfterSec|:30.0}
end doOpenURL

特定のアプリケーションでのみメニューバーアイテムを表示

property

property theMenuBarItemImage : "icon Evernote" --  -- メニューバーの画像。無い場合はmissing value
property theMenuBarTitle : "履歴" -- メニューバーのタイトル 。無い場合はmissing value
property theMenuBarItemDisplayAppNameList : {"Evernote", "AppleScript Editor"} -- 表示するアプリケーション名

doInitで返すレコードの値

|NSWorkspaceNotificationList|:{"NSWorkspaceDidActivateApplicationNotification"},

ハンドラ

on doNSWorkspaceDidActivateApplicationNotification(theNotificationName, theObject, theUserInfo, theActiveAppRecord, theThisAppRecord)
	
	set activeAppName to |name| of theUserInfo
	
	if (theMenuBarItemDisplayAppNameList does not contain activeAppName) and (|name| of theThisAppRecord is not activeAppName) then
		-- 隠す
		return {RemoveMenuBarItem:1}
	end if
	
	-- 表示
	return {|MenuBarItemImage|:theMenuBarItemImage, |MenuBarItemTitle|:theMenuBarTitle, |MenuItemList|:my getMenuItemList(theActiveAppRecord, theThisAppRecord)}
end doNSWorkspaceDidActivateApplicationNotification

ウインドウも特定のアプリケーションでのみ表示する場合のハンドラ

on doNSWorkspaceDidActivateApplicationNotification(theNotificationName, theObject, theUserInfo, theActiveAppRecord, theThisAppRecord)
	set activeAppName to |name| of theUserInfo
	
	if (theMenuBarItemDisplayAppNameList does not contain activeAppName) and (|name| of theThisAppRecord is not activeAppName) then
		-- 隠す
		-- ウインドウのvisibleを保存して全部隠す
		if 1 is |menuBarItemVisible| of theThisAppRecord then -- まだ隠してない時のみ隠す
			«event DictSetV» {"Var", "allWebViewWindowRecord", |allWebViewWindowRecord| of theThisAppRecord}
			«event Win_Hide»
			return {RemoveMenuBarItem:1}
		else
			return
		end if
	end if
	
	-- 表示
	if 0 is |menuBarItemVisible| of theThisAppRecord then
		«event Win_Show» («event DictGetV» {"Var", "allWebViewWindowRecord"}) -- 非表示から表示した時のみ表示する
	end if
	return {|MenuBarItemImage|:theMenuBarItemImage, |MenuBarItemTitle|:theMenuBarTitle, |MenuItemList|:my getMenuItemList(theActiveAppRecord, theThisAppRecord)}
end doNSWorkspaceDidActivateApplicationNotification

メニューバーアイテムをクリックした時に動的にメニューを作成して表示する

注意点

|MenuItemList|で、メニューアイテムが設定されているとそのメニューが表示されdoClickMenuBarItemは実行されず、動的にメニューを作れません。

他のレシピと併用する場合は|MenuItemList|を削除して下さい。

doInitで返すレコードの値

|SendActionOn|:{"LeftMouseDown"},

ハンドラ

on doClickMenuBarItem(theActiveAppRecord, theThisAppRecord)
	return {|PopUpMenuItemList|:my getMenuItemList(theActiveAppRecord, theThisAppRecord)}
end doClickMenuBarItem

メニューバーアイテムを右クリックでコンテキストメニューを表示する

ハンドラ

on doRightClickMenuBarItem(theActiveAppRecord, theThisAppRecord)
	return {|PopUpMenuItemList|:theRightClickMenuItemList}
end doRightClickMenuBarItem

リストからメニューリストを作成

スクリプト

	-- 処理対象のリスト
	set theWorkList to |allWebViewWindowNameList| of theThisAppRecord
	
	-- ソートするなら
	set {theWorkList, theResult} to «event HndlList» {theWorkList, "sort", "localizedStandardCompare"}
	
	-- タイトル用のprefixを付ける。付けなくてもほぼ大丈夫だけど---tagなどで始まるタイトルは表示されない
	set {theWorkList, theResult} to «event HndlList» {theWorkList, "prependTextToEveryItem", "---title "}
	
	-- メニューを選択した時に実行する処理の種類をtagで指定。メニューが複雑になってくると、tagでの判別が必要になってきます。
	set {theWorkList, theResult} to «event HndlList» {theWorkList, "insertAfterEveryItem", "---tag " & theSelectWindowTag}
	
	-- 特定の項目にチェックを付ける
	set checkTitle to |keyWindowName| of theThisAppRecord -- チェックを付けるタイトル
	set {theWorkList, theResult} to «event HndlList» {theWorkList, "insertAfterTheItem", "---title " & checkTitle, "---state on"}
	
	-- 完成

メニューアイテムを選択して設定をオンオフする。メニューアイテムにオンのチェックを付ける。

スクリプトに追加するには、最初に下のスクリプトを全部コピペしてから、theHogeSettingを自分の好きな名前に一括置換すると速いです。

property

property theSettingDictName : "Setting" -- 設定を保存する辞書の名前
property theHogeSettingTagAndKey : 1 -- 設定のタグとキー。数字で指定
property theHogeSettingDefaultValue : 1 -- 設定の初期値。1がオン、0がオフ
property theMenuItemList : { "設定", "---disable", "Hogeの設定", "---tag " & theHogeSettingTagAndKey, "---indentationLevel 1"}

doInit

	-- 初期値を辞書に登録
	«event DictSetD» {theSettingDictName, theHogeSettingTagAndKey, theHogeSettingDefaultValue}

メニュー作成

on getMenuItemList(theActiveAppRecord, theThisAppRecord)
	set theWorkList to theMenuItemList
	
	-- メニューアイテムにオンの場合チェックを付ける
	set {theWorkList, theResult} to «event HndlList» {theWorkList, "insertAfterTheItem", "---tag " & theHogeSettingTagAndKey, "---state " & («event DictGetV» {theSettingDictName, theHogeSettingTagAndKey})}
	
	return theWorkList
end getMenuItemList

メニュー選択

on doSelectMenuItem(theTitle, theTag, theActiveAppRecord, theThisAppRecord)
	if theTag is theHogeSettingTagAndKey then
		-- 設定のトルグ
		«event DictNotV» {theSettingDictName, theHogeSettingTagAndKey }
		my setMenuItem(theActiveAppRecord, theThisAppRecord) -- メニュー更新
	end if
end doSelectMenuItem

設定のオンオフを判定して処理

if 1 is («event DictGetV» {theSettingDictName, theHogeSettingTagAndKey}) then
	-- 設定がオンなので処理をする
end if

いくつかの値から選択するメニューアイテムを表示。選択したメニューアイテムにオンのチェックを付ける。

上のサンプルと似ていますが、これはある値のオンオフじゃなくて、数種類の値から選ぶメニューになります。

property

property theThemeMenuItemTag : 9 -- メニューアイテムに付けるタグ。重複しない任意の数値
property theDefaultThemeName : "Cosmo" -- デフォルト値
property theSettingDictName : "Setting" -- 設定を保存する辞書名
property theThemeNameKey : "ThemeName" -- 設定を保存する辞書のキー

property theMenuItemList : {"HTML テーマ", "---submenu", "Amelia", "---tag " & theThemeMenuItemTag, "Cerulean", "---tag " & theThemeMenuItemTag, "Cosmo", "---tag " & theThemeMenuItemTag, "Cyborg", "---tag " & theThemeMenuItemTag, "Journal Readable", "---tag " & theThemeMenuItemTag, "Simplex", "---tag " & theThemeMenuItemTag, "Slate", "---tag " & theThemeMenuItemTag, "Spacelab", "---tag " & theThemeMenuItemTag, "Spruce", "---tag " & theThemeMenuItemTag, "Superhero", "---tag " & theThemeMenuItemTag, "United", "---tag " & theThemeMenuItemTag, "---end submenu"}

doInit

	-- 初期値を辞書に登録
	«event DictSetD» {theSettingDictName, theThemeNameKey, theDefaultThemeName}

ハンドラ

on getMenuItemList(theActiveAppRecord, theThisAppRecord)
	set theWorkList to theMenuItemList
	
	-- 現在の値のメニューアイテムにチェックを付ける
	set theThemeName to «event DictGetV» {theSettingDictName, theThemeNameKey}
	set {theWorkList, theResult} to «event HndlList» {theWorkList, "insertAfterTheItem", theThemeName, "---state 1"}
	
	
	return theWorkList
end getMenuItemList

on doSelectMenuItem(theTitle, theTag, theActiveAppRecord, theThisAppRecord)
	-- メニュー選択時の処理
	if theTag is theThemeMenuItemTag then
		-- メニューを選択したので値を保存して、メニューを更新
		«event DictSetV» {theSettingDictName, theThemeNameKey, theTitle}
		my setMenuItem(theActiveAppRecord, theThisAppRecord)
	end if
end doSelectMenuItem

on setMenuItem(theActiveAppRecord, theThisAppRecord)
	«event MBASHndl» {|MenuItemList|:my getMenuItemList(theActiveAppRecord, theThisAppRecord)}
end setMenuItem

	set theHTMLTheme to «event DictGetV» {theSettingDictName, theThemeNameKey}
-- theHTMLThemeに選択した値が入っているので処理をする

iTunesの曲が変わった時に処理をする

曲が変わった通知を受け取ります。

doInitで返すレコードの値

|NSDistributedNotificationList|:{"com.apple.iTunes.playerInfo"},

ハンドラ

on docom_apple_iTunes_playerInfo(theNotificationName, theObject, theUserInfo, theActiveAppRecord, theThisAppRecord)
	-- NSDistributedNotificationのcom.apple.iTunes.playerInfoの通知を受けた時に実行されます
	
	-- theUserInfoに曲の情報が入っています
	-- 次のようにして取り出します
	-- set theName to |Name| of theUserInfo
	
	-- 停止中はメニューバーから取り除く
	if |Player State| of theUserInfo is "Paused" then
		-- 停止した時の処理
		return {}
	end if
	
	-- Playing以外の場合はハンドラを終了
	-- PausedとPlaying以外あるかどかはわかりません
	if |Player State| of theUserInfo is not "Playing" then
		-- 再生していない時の処理
		return {}
	end if
	
	
	tell application "iTunes"
		-- theUserInfoから通知で受けた曲を取り出すには次のようにpersistent IDを使います
		-- current trackでもだいたいいいと思います
		set thePlaylistList to every playlist whose persistent ID is |Playlist PersistentID| of theUserInfo
		set thePlaylist to item 1 of thePlaylistList
		set theTrackList to every track of thePlaylist whose persistent ID is |PersistentID| of theUserInfo
		set theTrack to item 1 of theTrackList -- theTrackがtheUserInfoで受け取ったtrackになります
		
		-- 処理をする
		
	end tell
end docom_apple_iTunes_playerInfo

Safariのダウンロードが完了した時にハンドラを実行

doInitで返すレコードの値

|NSDistributedNotificationList|:{"com.apple.DownloadFileFinished"},

ハンドラ

on docom_apple_DownloadFileFinished(theNotificationName, theObject, theUserInfo, theActiveAppRecord, theThisAppRecord)
	-- theObjectにダウンロードしたファイルのパスが入っています
	
	set theDownloadFilePath to theObject
	
	-- 処理をする
	
end docom_apple_DownloadFileFinished

ネットの接続状態が変わった時にハンドラを実行

doInitで返すレコードの値

|SCNotificationList|:{"State:/Network/Global/IPv4"}, |RunSCNotificationHandler|:1, 

ハンドラ

on doState__Network_Global_IPv4(theValue, theActiveAppRecord, theThisAppRecord)
	-- ネットに繋がっているかチェックして記憶
	if theValue is not missing value then
		-- ネットに繋がっている
		set theNetworkStatus to true
	else
		-- ネットに繋がっていない
		set theNetworkStatus to false
	end if
end doState__Network_Global_IPv4

ホットキーを登録、押した時にスクリプトを実行：グローバル

doInitで返すレコードの値

|HotKeyList|:{{|Name|:"RateUp", |KeyChar|:"up", |ModifierKeyList|:{"shift", "option"}, |Enable|:1 }, {|Name|:"RateDown", |KeyChar|:"down", |ModifierKeyList|:{"shift", "option"}, |Enable|:1}}, 

propertyにホットキーの設定を書く場合

-- ホットキー設定 変更した場合は要アプリケーションの再起動
property theEnableHotKey : 0 -- ホットキーを有効にするなら1 無効なら 0
property theHotKeyKey : "right" -- ホットキーのキー
property theHotKeyModifierKeyList : {"command", "control"} -- ホットキーの修飾キー

|HotKeyList|:{{|Name|:"RateUp", |KeyChar|:theHotKeyKey, |ModifierKeyList|:theHotKeyModifierKeyList, |Enable|:theEnableHotKey}}, 

ハンドラ

on doHotKeyRateUp(theActiveAppRecord, theThisAppRecord)
	
	-- ホットキーを押した時の処理
	
end doHotKeyRateUp

ホットキーを登録、押した時にスクリプトを実行：アプリのみ

doInitで返すレコードの値

|AppHotKeyList|:{{|Name|:"RateUp", |KeyChar|:"up", |ModifierKeyList|:{"shift", "option"}, |Enable|:1 }, {|Name|:"RateDown", |KeyChar|:"down", |ModifierKeyList|:{"shift", "option"}, |Enable|:1}}, 

propertyにホットキーの設定を書く場合

-- ホットキー設定 変更した場合は要アプリケーションの再起動
property theEnableHotKey : 0 -- ホットキーを有効にするなら1 無効なら 0
property theHotKeyKey : "right" -- ホットキーのキー
property theHotKeyModifierKeyList : {"command", "control"} -- ホットキーの修飾キー

|AppHotKeyList|:{{|Name|:"RateUp", |KeyChar|:theHotKeyKey, |ModifierKeyList|:theHotKeyModifierKeyList, |Enable|:theEnableHotKey}}, 

ハンドラ

on doAppHotKeyRateUp(theActiveAppRecord, theThisAppRecord)
	
	-- ホットキーを押した時の処理
	
end doAppHotKeyRateUp

MenuBarAppleScriptでテスト用スクリプトを実行

可能ならデバッグ方法を使用したほうがイベントログが確認できます。

ハンドラ

on run
	set theApp to (path to me) as Unicode text
	tell application theApp
		«event MBASRunH» {|Handler|:"Test"}
	end tell
end run

on doHandlerTest(theRecord, theActiveAppRecord, theThisAppRecord)
	-- ここにテスト用スクリプトを書く
	-- MenuBarAppleScriptで実行されるので各種MenuBarAppleScriptの命令が使えます
	say "test"
end doHandlerTest

疑似スレッド

コマンドの非同期実行でosascriptを実行して、MenuBarAppleScriptのスクリプトのハンドラを実行して擬似的にスレッドを実現しているものです。

スレッド間での値の受け渡しは辞書(ハッシュ)関係の命令を使い、MenuBarAppleScriptを起点に行うことができます。MenuBarAppleScriptの命令はアプリケーションのメインスレッドで実行されるので、別のスレッドから同時に実行しても大丈夫です。

スレッドではpropertyは使えますが、初期値は保証されません。また、他のスレッド間でpropertyの値を共有することはできません。初期化してそのスクリプト中で使うことはできます。

MenuBarAppleScriptThread.scptは最新のMenuBarAppleScriptにはバンドルの中に入っています。

ハンドラ

	-- 新規スレッドで実行
	my detachNewThread("Test", {"hoge", "neko"})

on detachNewThread(theThreadHandler, theUserInfo)
	-- スレッド作成
	set appInfoRecord to «event InfoTApp»
	set theThreadNumber to «event DictNum_» {"ThreadUserInfo", "ThreadNumber", "+", 1}
	set theThreadNumberStr to theThreadNumber as text
	«event DictSetV» {"ThreadUserInfo", theThreadNumberStr, theUserInfo}
	
	set theThreadScriptPath to (|scriptsFolderPath| of appInfoRecord) & "MenuBarAppleScriptThread.scpt"
	«event Cmd_Run_» {|CommandPath|:"/usr/bin/osascript", |ArgvList|:{theThreadScriptPath, |bundleIdentifier| of appInfoRecord, theThreadHandler, theThreadNumberStr}, |Handler|:"FinishThread" & theThreadHandler, |ThreadNumber|:theThreadNumber, |UserInfo|:theUserInfo}
end detachNewThread

on doThreadTest(theBundleIdentifier, theThreadNumberStr)
	try
		-- スレッドで実行されるハンドラ
		tell application id theBundleIdentifier
			-- 元のアプリケーションにtell
			set theUserInfo to «event DictGetV» {"ThreadUserInfo", theThreadNumberStr}
			«event DebugLog» {"UserInfo", theUserInfo}
			
			-- 時間がかかる処理など
			
			
			«event DictDelV» {"ThreadUserInfo", theThreadNumberStr} -- UserInfoを削除しておく
		end tell
		return "abc"
	on error msg
		«event DebugLog» "Thread Error"
		«event DebugLog» msg
	end
end doThreadTest

on doCommandResultFinishThreadTest(theOutputText, theErrorText, theTerminationStatus, theCommandRecord, theActiveAppRecord, theThisAppRecord)
	-- スレッド終了時に実行されるハンドラ
	-- theOutputTextの末尾には改行が付加されているようです。
	«event DebugLog» {"ThreadResult", theOutputText}
	«event DebugLog» theCommandRecord
end doCommandResultFinishThreadTest

特定のメニューが選択された時にハンドラを実行

例：ファイルメニューの保存がCmd + Sやメニューアイテムを選択して実行された時にハンドラを実行します。

doInitで返すレコードの値

{|AXNotificationList|:{{|AppName|:"Evernote", |Enable|:1, |NotificationList|:{{|Name|:"AXMenuItemSelected", |Enable|:1, |TargetList|:{"AXMenuBar", "", "AXTitle", "ファイル", "AXRole", "AXMenu", "AXTitle", "保存"}}}}}}

ハンドラ

on doAXMenuItemSelected(theAXAppRecord, theActiveAppRecord, theThisAppRecord)
	-- メニューが選択された
end doAXMenuItemSelected

アプリケーションを再度開いた時にダイアログで確認して終了する

GUIが全く無いアプリケーションに書いておくと終了できるようになります。

ハンドラ : ダイアログ

on doReOpen(theActiveAppRecord, theThisAppRecord)
	set theName to |name| of theThisAppRecord
	activate
	display dialog theName & "を終了します" buttons {"Cancel", "OK"} default button 2
	if the button returned of the result is "OK" then
		quit
	end if
end doReOpen

アプリケーションを再度開いた時にコンテキストメニューを表示する

メニューに終了とログイン時に自動的に起動する設定を表示しておけば、終了したり、その設定ができるようになります。

property

|AutoAddQuitMenuItem|:1, |AutoAddLaunchOnLoginMenuItem|:1, |AutoAddVersionMenuItem|:1,

ハンドラ : コンテキストメニュー

on doReOpen(theActiveAppRecord, theThisAppRecord)
	set theName to |name| of theThisAppRecord
	«event MBASHndl» {|ContextMenuItemList|:{theName}}
end doReOpen

アクティブなアプリケーションのフォーカスが当たっているTextAreaを操作する

テキストの取得、選択しているテキストの取得、テキストの選択、選択しているテキストへスクロール、指定したテキストへスクロールができます。

ハンドラ

on getFocusedUIElementText(theActiveAppRecord)
	-- ver.2012.12.25.00
	-- フォーカスが当たっているAXTextFieldかAXTextAreaのテキストを取得
	«event UIElSetE» {|name| of theActiveAppRecord, {"AXFocusedUIElement", ""}}
	set {theRole, theValue} to «event UIElGetV» {"AXRole", "AXValue"}
	if {"AXTextField", "AXTextArea"} does not contain theRole then
		return ""
	end if
	return theValue
end getFocusedUIElementText

on getFocusedUIElementSelectedText(theActiveAppRecord)
	-- ver.2012.12.25.00
	-- フォーカスが当たっているAXTextFieldかAXTextAreaの選択しているテキストを取得
	«event UIElSetE» {|name| of theActiveAppRecord, {"AXFocusedUIElement", ""}}
	set {theRole, theSelectedText} to «event UIElGetV» {"AXRole", "AXSelectedText"}
	if {"AXTextField", "AXTextArea"} does not contain theRole then
		return ""
	end if
	
	return theSelectedText
end getFocusedUIElementSelectedText

on focusedUIElementSelectText(theActiveAppRecord, theSelectText)
	-- ver.2012.12.31.00
	-- フォーカスが当たっているAXTextField、AXTextAreaの指定したテキストを選択する
	«event UIElSetE» {|name| of theActiveAppRecord, {"AXFocusedUIElement", ""}}
	set {theRole, theValue} to «event UIElGetV» {"AXRole", "AXValue"}
	if {"AXTextField", "AXTextArea"} does not contain theRole then
		return false
	end if
	
	set pos to offset of theSelectText in theValue
	if pos is 0 then
		return false
	end if
	
	set theLen to (count of theSelectText)
	set pos to pos - 1
	«event UIElSetV» {"AXSelectedTextRange", "pos=" & pos & " len=" & theLen}
	«event UIElSetV» {"AXVisibleCharacterRange", "pos=" & pos & " len=" & theLen}
	return true
end focusedUIElementSelectText


on focusedUIElementScrollToSelection(theActiveAppRecord)
	-- ver.2012.12.25.00
	-- フォーカスが当たっているAXTextAreaを選択しているテキストかカーソルがある位置にスクロールする
	«event UIElSetE» {|name| of theActiveAppRecord, {"AXFocusedUIElement", ""}}
	set {theRole, theRange} to «event UIElGetV» {"AXRole", "AXSelectedTextRange"}
	if theRole is not "AXTextArea" then
		return
	end if
	
	«event UIElSetV» {"AXVisibleCharacterRange", theRange}
end focusedUIElementScrollToSelection

on focusedUIElementScrollToText(theActiveAppRecord, theSelectText)
	-- ver.2012.12.25.00
	-- AXTextAreaで指定したテキストを表示するようにスクロールする。
	-- テキストが複数ある場合は最初のものが対象になる
	«event UIElSetE» {|name| of theActiveAppRecord, {"AXFocusedUIElement", ""}}
	set {theRole, theVisibleCharacterRange, theValue} to «event UIElGetV» {"AXRole", "AXVisibleCharacterRange", "AXValue"}
	if theRole is not "AXTextArea" then
		return ""
	end if
	
	set pos to offset of theSelectText in theValue
	if pos is 0 then
		return "no text"
	end if
	
	set {theVPos, theVLen} to my rangeTextToList(theVisibleCharacterRange)
	
	if theVPos ≤ pos and pos ≤ (theVPos + theVLen) then
		-- すでに画面に表示されている場合はスクロールしない
		return "visible"
	end if
	
	«event UIElSetV» {"AXVisibleCharacterRange", "pos=" & pos & " len=1"}
	return "scroll"
end focusedUIElementScrollToText

on rangeTextToList(theRange)
	-- ver.2012.12.25.00
	set {thePos, theLen} to «event TextRegx» {"capture", "pos=([0-9]+) len=([0-9]+)", theRange, {1, 2}}
	set thePos to thePos + 1 -- AppleScriptは1ベースなので
	return {thePos, theLen}
end rangeTextToList

指定したアプリケーションのフォーカスが当たっているUIElementのテキストを可能な限り取得する

AXTextField,AXTextArea,AXWebAreaなどが取得できます。

クリップボード、サービスを使わずにかなりの状況でテキストを取得できると思います。

-- 指定したアプリケーションのフォーカスが当たっているUI Elementのテキストを取得
if 1 is «event UIElSetE» {"Evernote", {"Attr", "AXFocusedUIElement"}} then
	set {theRole, theAllText, theSelectedText, theSelectedRangeList, theInsertionWord, theInsertionLine, theTerm} to my getUIElementText("Evernote", "InsertionWord")
end


on getUIElementText(theGetOption)
	-- ver.2013.01.30.00	
	
	-- UIElの選択しているテキストなどを取得する
	-- "AXTextField", "AXTextArea", "AXWebArea" などから取得できる
	
	-- theAppName : 対象のアプリケーション名　英語名で指定
	
	-- theGetOption :
	-- "InsertionWord"で挿入部分の単語(同じ種類の文字の連続)と行を取得。対象が"GetOption"と繋がっている場合は"GetOption"を返します。
	-- "Term"で辞書サービスで単語を取得 。単語を取得します。対象が"GetOption"と繋がっていても"Get"や"Option"を返します。
	-- 複数指定する場合ははスペースで繋げる
	--  ""で未指定
	
	-- 注意
	-- AXWebAreaはテキストを選択している場合、theSelectedRangeListがちゃんと取得できない場合がある。
	-- その為、 theInsertionWord, theInsertionLineもちゃんと取得できない場合がある
	
	-- 使い方
	-- set {theRole, theAllText, theSelectedText, theSelectedRangeList, theInsertionWord, theInsertionLine, theTerm} to my getUIElementText("InsertionWord Term")
	
	-- theInsertionWordはカーソル位置の文字の英数字、ひらがな、カタカナ、漢字の連続した部分です。
	
	tell me
		try
			set theRole to missing value
			set theAllText to missing value
			set theSelectedText to missing value
			set theSelectedRangeList to missing value
			set theInsertionWord to ""
			set theInsertionLine to ""
			set theTerm to missing value
			
			set {theRole} to «event UIElGetV» {"AXRole"}
			
			if theRole is "AXWebArea" then
				«event UIElVal_» {"AXTextMarkerRangeForUIElement", "UIEl", "AllTextMarkerRange"}
				set theAllText to «event UIElVal_» {"AXStringForTextMarkerRange", "AllTextMarkerRange", ""}
				
				«event UIElVal_» {"AXSelectedTextMarkerRange", "", "SelectedTextMarkerRange"}
				set theSelectedText to «event UIElVal_» {"AXStringForTextMarkerRange", "SelectedTextMarkerRange", ""}
				
				set theBounds to «event UIElVal_» {"AXBoundsForTextMarkerRange", "SelectedTextMarkerRange", ""} -- ,
				if theBounds is not missing value then
					set {theX, theY, theWidth, theHeight} to «event TextRE__» {"capture", theBounds, "x=(-?\\d+) y=(-?\\d+) w=(-?\\d+) h=(=?\\d+)", {1, 2, 3, 4}}
					
					«event UIElVal_» {"AXTextMarkerForPosition", "x=" & theX & " y=" & theY, "StartSelectionTextMarker"}
					«event UIElVal_» {"AXStartTextMarker", "", "StartTextMarker"}
					«event UIElVal_» {"AXTextMarkerRangeForUnorderedTextMarkers", {"StartTextMarker", "StartSelectionTextMarker"}, "StartToStartSelectionMarkerRange"} -- ,
					
					set StartToStartSelectionText to «event UIElVal_» {"AXStringForTextMarkerRange", "StartToStartSelectionMarkerRange", ""}
					set theSelectedRangeList to {1 + (count of StartToStartSelectionText), count of theSelectedText}
				else
					set theSelectedRangeList to missing value
				end if
			else
				set {theAllText, theSelectedText, theSelectedTextRange} to «event UIElGetV» {"AXValue", "AXSelectedText", "AXSelectedTextRange"}
				
				if theSelectedTextRange is not missing value then
					set {thePos, theLen} to «event TextRE__» {"capture", theSelectedTextRange, "pos=(-?\\d+) len=(-?\\d+)", {1, 2}}
					set theSelectedRangeList to {thePos + 1, theLen}
				end if
			end if
			
			
			
			if ((theGetOption contains "Insertionword") or (theGetOption contains "Term")) and (theAllText is not missing value) and (theAllText is not "") and (theSelectedRangeList is not missing value) then
				set theAllTextLen to count of theAllText
				set theSelPos to (item 1 of theSelectedRangeList)
				
				if (item 2 of theSelectedRangeList) > 0 then
					set theSelPos to theSelPos + (item 2 of theSelectedRangeList) - 1
				end if
				
				if theSelPos < 1 then
					set theSelPos to 1
				end if
				
				if theSelPos > theAllTextLen then
					set theSelPos to theAllTextLen
				end if
				
				if (theGetOption contains "Term") then
					set {theTerm, theRange} to «event DicSTerm» {theAllText, theSelPos}
				end if
				
				
				if (theGetOption contains "insertionword") then
					set theInsertionWord to text theSelPos of theAllText
					
					set theGetLineRegex to "([^\\n\\r]+)"
					set theRegexList to {theGetLineRegex, "([-_A-Za-z0-9]+)", "(\\p{Hiragana}+)", "([\\p{Katakana}ー]+)", "(\\p{Han}+)"}
					repeat with theRegexItem in theRegexList
						set theRegex to contents of theRegexItem
						if (1 is («event TextRE__» {"isMatched", theInsertionWord, theRegex})) then
							
							if theSelPos > 1 then
								set theText to text 1 thru (theSelPos - 1) of theAllText
								set theText to «event TextRE__» {"capture", theText, theRegex & "\\z", 1}
								if theText is not missing value then
									set theInsertionWord to theText & theInsertionWord
								end if
							end if
							
							if theSelPos < theAllTextLen then
								set theText to text (theSelPos + 1) thru -1 of theAllText
								set theText to «event TextRE__» {"capture", theText, "^" & theRegex, 1}
								if theText is not missing value then
									set theInsertionWord to theInsertionWord & theText
								end if
							end if
							
							if theRegex is theGetLineRegex then
								set theInsertionLine to theInsertionWord
								set theInsertionWord to text theSelPos of theAllText
							else
								exit repeat
							end if
						else if theRegex is theGetLineRegex then
							-- 前の行を取得
							if theSelPos > 1 then
								set theText to text 1 thru (theSelPos - 1) of theAllText
								set theText to «event TextRE__» {"capture", theText, theRegex & "\\z", 1}
								if theText is not missing value then
									set theInsertionLine to theText
								end if
							end if
						end if
					end repeat
				end if
			end if
		on error
			set theRole to missing value
			set theAllText to missing value
			set theSelectedText to missing value
			set theSelectedRangeList to missing value
			set theInsertionWord to ""
			set theInsertionLine to ""
			set theTerm to missing value
		end try
		return {theRole, theAllText, theSelectedText, theSelectedRangeList, theInsertionWord, theInsertionLine, theTerm}
	end tell
	
end getUIElementText

Finderの選択している項目が変わった時に処理をする

選択しているものが変わったことはわかりますが、何を選択しているかは通知ではわからないのでselectionで調べて下さい。

property

|AXNotificationList|:{{|AppName|:"Finder", |NotificationList|:{{|Name|:"AXSelectedRowsChanged", |Target|:"*"}, {|Name|:"AXSelectedChildrenChanged", |Target|:"*"}}}}

ハンドラ

on doAXSelectedChildrenChanged(theAXAppRecord, theActiveAppRecord, theThisAppRecord)
	-- アイコン表示で選択した項目が変わった。選択したファイルはFinderのselectionで取得します。
	-- ファイル以外のものを選択した場合も実行されると思うので、選択したファイルが変わっているか調べる等して下さい
	my FinderSelectionChanged()
end doAXSelectedChildrenChanged

on doAXSelectedRowsChanged(theAXAppRecord, theActiveAppRecord, theThisAppRecord)
	-- リスト表示で選択した項目が変わった。選択したファイルはFinderのselectionで取得します。
	-- ファイル以外のものを選択した場合も実行されると思うので、選択したファイルが変わっているか調べる等して下さい
	my FinderSelectionChanged()
end doAXSelectedRowsChanged

on FinderSelectionChanged()
	try
		tell application "Finder"
			set theSelectionAliasList to selection as alias list
		end tell
	on error
		return
	end try
	
	repeat with theAlias in theSelectionAliasList
		-- 処理をする
	end repeat
end FinderSelectionChanged

FSEventでフォルダの変更を調べる

アプリケーションに返すレコードの値

doInit以外でもOK

|FSEventFolderList|:{"/path/to/check/folder/"}

ハンドラ

on doFSEvent(theEventPathList, theActiveAppRecord, theThisAppRecord)
 -- 変更があった
end

JavaScriptとの連携

"CalSearch"を好きな名前に変えて下さい。

JavaScriptからMenuBarAppleScriptのハンドラを実行

次のJavaScriptでブラウザで動作確認できます。

var result = "";
if( window.MenuBarAppleScript )
{
	result = window.MenuBarAppleScript.runHandler("CalSearch","MenuBarAppleScriptに渡す値");
	// 文字列、数値、リストを渡すことができます
	//result = window.MenuBarAppleScript.runHandler("Sample",[ 1, 2, [ "a", "b" ] ] );
	// AppleScript側ではtheValueが { 1, 2, { "a", "b" } } になります。
}
else
{
	result = "hoge";	// ブラウザで動作確認用のresult
}

// HTMLの状態はLocal Storageでセーブ、ロードできます。
var settingA =localStorage.getItem('settingA'); -- ロード
localStorage.setItem('settingA', $(this).val()); -- セーブ

JavaScriptから実行されたハンドラ

on doHandlerFromJavaScriptCalSearch(theValue, theActiveAppRecord, theThisAppRecord)
	--	«event DebugLog» {"doHandlerFromJavaScriptCalSearch"}

	-- 処理をする
	set theResult to "結果"
	
	return {|Result|:theResult} -- JavaScriptに返す値
	return {|Result|: { theResult, 1, 2 } } -- リストを返すとJavaScriptでは配列になります

end doHandlerFromJavaScriptCalSearch

WebViewWindowを表示、作るハンドラ

property theWindowName : "ウインドウ名"

on showWindow(theActiveAppRecord, theThisAppRecord)
	-- ウインドウが無ければ作成して表示、あればそれを表示
	if (|allWebViewWindowNameList| of theThisAppRecord) does not contain theWindowName then
		my makeWindow(theActiveAppRecord, theThisAppRecord)
	end if
	«event Win_Show» theWindowName
end showWindow

on hideWindow(theActiveAppRecord, theThisAppRecord)
	«event Win_Hide» theWindowName
end hideWindow

on makeWindow(theActiveAppRecord, theThisAppRecord)
	set theHTMLURL to (|resourcesFolderURL| of theThisAppRecord) & "datepicker/index.html"
	
	«event MBASHndl» {|WebViewWindow|:{|URL|:theHTMLURL, |Name|:theWindowName, |Title|:theWindowName, |Visible|:0, |Activate|:0, |Width|:228, |Height|:400, |Delete|:0, |AllowsScrolling|:0, |Alpha|:1.0, |Opaque|:0, |Level|:"FloatingWindowLevel", |StyleList|:{"Titled", "Utility", "Closable", "HUD"}, |CanHide|:1, |HasShadow|:1, |AcceptsFirstMouse|:1}}
end makeWindow

WebViewWindowでページの読み込み完了まで待ってJavaScriptを実行

doDidFinishLoadForFrameでページの読み込み完了時に処理をできますが、この場合処理が分離されるので、JavaScriptでページの値を取得してそれを処理をする場合などはすごい面倒になります。

そこで、ページの読み込み完了まで待ってJavaScriptを実行するサンプルです。

	set theTmpWindowName to "tmp"
	set theURL to "http://tv.yahoo.co.jp/listings/"
	-- 画像やプラグインをオフにしておくと読み込みがちょっと早いと思う
	-- ただし、一度オフにするとずっとオフになるので次にウインドウを作る時は
	-- |LoadsImagesAutomatically|:1, |PlugInsEnabled|:1, |JavaEnabled|:1
	-- を必要に応じてウインドウ作成時に指定して下さい。
	«event MBASHndl» {|WebViewWindow|:{|Name|:theTmpWindowName, |URL|:theURL, |Width|:512, |Height|:512, |Visible|:0, |LoadsImagesAutomatically|:0, |PlugInsEnabled|:0, |JavaEnabled|:0}}
	repeat 100 times
		delay 0.2
		if 0 is («event WebVUtil» {theTmpWindowName, "isLoading"}) then
			exit repeat
		end if
	end repeat
	
	set theJavaScript to "
	var text = '';
	var result = document.evaluate('id(\"ListingsHeader\")//td[@class=\"station\"]//a//text()', document, null, XPathResult.ORDERED_NODE_SNAPSHOT_TYPE, null);
for(var i=0;i<result.snapshotLength;i++){
	var node = result.snapshotItem(i);
	text += node.textContent + '<>';
}
return text;
"
	
	-- return で値を返せるように囲っておく
	set theJavaScript to "(function(){" & theJavaScript & ";})();"
	
	set theChannel to «event WebVUtil» {theTmpWindowName, "doJavaScript", theJavaScript}
	
	-- XPath 例2
	set theJavaScript to "
	var text = '';
	var result = document.evaluate('id(\"ListingsMargin\")/following-sibling::*[1][local-name()=\"table\"]/tbody/tr[1]//td', document, null, XPathResult.ORDERED_NODE_SNAPSHOT_TYPE, null);
for(var i=0;i<result.snapshotLength;i++){
	var node = result.snapshotItem(i);
	text += node.innerText + '<>';
}

return text;
"
	set theJavaScript to "(function(){" & theJavaScript & ";})();"
	
	set theInfo to «event WebVUtil» {theTmpWindowName, "doJavaScript", theJavaScript}


	«event MBASHndl» {|WebViewWindow|:{|Name|:theTmpWindowName, |Delete|:1 } } 

«event UIElSetE»のレシピ

«event UIElSetE»で処理対象を指定するサンプルです。

フォーカスが当たっているUI Elementを対象とする

«event UIElSetE» {"AppleScript Editor", {"Attr", "AXFocusedUIElement"}}

基本でよく使います

テキスト編集中ならAXTextArea、AXWebAreaなどになります。

アクティブなウインドウのAXWebAreaを探して対象とする

«event UIElSetE» {"Safari", {"Attr", "AXFocusedWindow", "AnyRole", "(AXSplitGroup|AXGroup|AXScrollArea|AXTabGroup)", "AXRole", "AXWebArea"}}

AnyRoleを使うとAXWebAreaがどのAXGroupのどのAXSplitGroupに入っているなどを知らなくてもAXWebAreaを取得できます。

普通にAppleScriptのGUIスクリプティングでAXWebViewを指定しようとすると、Safari,Evernote,Mail,Dictionaryなどすべて指定方法が違いますが、AnyRoleを使った上記記述法で書くとアプリケーション名を変えるだけでほぼすべてのアプリケーションで同じスクリプトでウインドウに表示されているAXWebAreaを指定できます。

アクティブなウインドウの"ノートリスト"という名前のAXTableを探して対象とする

«event UIElSetE» {"Evernote", {"Attr", "AXFocusedWindow", "AnyRole", "(AXSplitGroup|AXGroup|AXScrollArea|AXTabGroup)", "AXRole AXTitle", "^AXTable \\Qノートリスト\\E$"}}

上のAXWebAreaと同じですが、探しているタイプのUI Elementが複数あり、タイトルで指定したい場合。

タイトルを\\Qと\\Eで囲っているのは探しているタイトルに正規表現のメタ文字がある場合に備えてです。

UIElがテーブルの時に、AppleScriptというテキストを表示しているAXRowを探して対象とする

«event UIElSetE» {"Evernote", {"UIEl", "", "AXRole", "AXRow", "AXRole AXValue", "^AXTextField \\QAppleScript\\E$", "Attr", "AXParent"}}

AttrでAXParentを取得すると一度子まで調べてその親を対象に出来ます。

UIElがAXOutlineの時に閉じているフォルダを開く

«event UIElSetE» {"Evernote", {"UIEl", "", "AXRole", "AXRow", "AXRole", "AXGroup", "AXRole AXValue", "AXDisclosureTriangle 0", "PerformAction", "AXPress"}}

探した閉じているフォルダのAXRowに対してPerformActionでAXPressを送って展開させています。

«event UIElSetE»でGUI操作ハンドラ

«event UIElSetE»でGUIを操作するハンドラです。どのAXGroupやAXScrollAreaに入っているかなどは指定する必要がなくて、タイトルなどそのUI Elementの属性で指定できます。

set theAppName to "System Preferences"
my setSliderValue(theAppName, "AXDescription", "Dock のサイズつまみ", 0.1)
my clickMenuItem(theAppName, "アーカイブ")
my selectPopupButton(theAppName, "AXValue", "(スケール|ジニー)", "ジニーエフェクト")
my clickButton(theAppName, "プロファイルを開く")
my setCheckAndRadioButtonValue(System, "拡大：", 1)
my selectTab("System Preferences", "AXValue", ".*(設定|コマンド).*", "設定")
	
on selectTab(theAppName, theTargetTabAttr, theTargetTabValue, theSelectTabTitle)
	-- ver.2013.01.06.00
	tell me
		if 0 is not («event UIElSetE» {theAppName, {"Attr", "AXFocusedWindow", "AnyRole", "(AXSplitGroup|AXGroup|AXScrollArea|AXTabGroup)", "AXRole " & theTargetTabAttr, "AXTabGroup " & theTargetTabValue & "", "Attr", "AXTabs", "FindSelf", "", "AXTitle", "^\\Q" & theSelectTabTitle & "\\E$", "PerformAction", "AXPress"}}) then
			return true
		end if
		return false
	end tell
end selectTab

on setSliderValue(theAppName, theTargetSliderAttr, theTargetSliderValue, theValue)
	-- ver.2013.01.09.00
	tell me
		if 0 is not («event UIElSetE» {theAppName, {"Attr", "AXFocusedWindow", "AnyRole", "(AXSplitGroup|AXGroup|AXScrollArea|AXTabGroup)", "AXRole " & theTargetSliderAttr, "^AXSlider \\Q" & theTargetSliderValue & "\\E$"}}) then
			«event UIElSetV» {"AXValue", theValue}
			return true
		end if
		return false
	end tell
end setSliderValue

on setCheckAndRadioButtonValue(theAppName, theButtonTitle, theValue)
	-- ver.2013.01.06.00
	-- 1でオン、0でオフ
	tell me
		if theValue is 1 then
			set theCurrentValue to "0"
		else
			set theCurrentValue to "1"
		end if
		if 0 is not («event UIElSetE» {theAppName, {"Attr", "AXFocusedWindow", "AnyRole", "(AXSplitGroup|AXGroup|AXScrollArea|AXTabGroup)", "AXRole AXValue AXTitle", "^(AXCheckBox|AXRadioButton) " & theCurrentValue & " \\Q" & theButtonTitle & "\\E$", "PerformAction", "AXPress"}}) then
			return true
		end if
		
		return false
	end tell
end setCheckAndRadioButtonValue

on clickButton(theAppName, theButtonTitle)
	if 0 is not («event UIElSetE» {theAppName, {"Attr", "AXFocusedWindow", "AnyRole", "(AXSplitGroup|AXGroup|AXScrollArea|AXTabGroup)", "AXTitle", "^\\Q" & theButtonTitle & "\\E$", "PerformAction", "AXPress"}}) then
		return true
	end if
	
	return false
end clickButton

on selectPopupButton(theAppName, theTargetPopupAttr, theTargetPopupValue, theSelectTitle)
	-- ver.2013.01.06.00
	tell me
		if 0 is not («event UIElSetE» {theAppName, {"Attr", "AXFocusedWindow", "AnyRole", "(AXSplitGroup|AXGroup|AXScrollArea|AXTabGroup)", "AXRole " & theTargetPopupAttr, "AXPopUpButton " & theTargetPopupValue & "", "PerformAction", "AXPress"}}) then
			if 0 is not («event UIElSetE» {theAppName, {"UIEl", "", "AnyRole", "(AXMenu|AXMenuItem)", "AXTitle", "^\\Q" & theSelectTitle & "\\E$", "PerformAction", "AXPress"}}) then
				return true
			end if
		end if
		return false
	end tell
end selectPopupButton

-- 下のより «event UIElPAct» を使ったほうが動作が安定するようです。
on clickMenuItem(theAppName, theMenuItemTitle)
	-- ver.2013.07.28.00
	tell application theAppName to activate
	tell me
		if 0 is not («event UIElSetE» {theAppName, {"Attr", "AXMenuBar", "AnyRole", "(AXMenu|AXMenuItem)", "AXRole AXEnabled AXTitle", "^AXMenuItem 1 \\Q" & theMenuItemTitle & "\\E$"}}) then
			«event UIElPAct» {"AXPress"}
			return true
		end if
		return false
	end tell
end clickMenuItem


-- «event UIElSetE» 1行で書く場合。指定したメニュー実行後にメニューが表示されるケースが有りました。
on clickMenuItem_2(theAppName, theMenuItemTitle)
	-- ver.2013.04.19.00
	tell application theAppName to activate
	tell me
		if 0 is not («event UIElSetE» {theAppName, {"Attr", "AXMenuBar", "AnyRole", "(AXMenu|AXMenuItem)", "AXRole AXEnabled AXTitle", "^AXMenuItem 1 \\Q" & theMenuItemTitle & "\\E$", "PerformAction", "AXPress"}}) then
			return true
		end if
		return false
	end tell
end clickMenuItem

WebViewで実行したJavaScriptの結果を確実に返す

JavaScriptの途中でreturnで値を返すとその結果を取得できない場合があります。それの対策にはスクリプトを次のようにします。

-- 実行したいJavaScript
set theJavaScript to "hoge(); if( ! hage ){ return 'fusafusa';} katsura();"

-- これでスクリプトを囲む
set theJavaScript to "(function(){" & theJavaScript & ";})();"

-- 実行する
set theResult to «event WebVJS__» {theWindowName, theJavaScript}  

DoAtTimeで指定時間にハンドラを実行する：自動繰り返し

DoAtTimeのサンプルです。

スリープから復帰時がややこしいですが、下記サンプルで細かいところまで対処できていると思います。あまり動作テストはしてませんが…。

スリープからの復帰時に気をつけることは、予定時間を過ぎていた、複数指定して複数の予定時間を過ぎていたです。下の例では、複数の予定時間を過ぎていた場合でも1回だけ処理を実行します。すべての予定時間分の処理を行う場合はDoOnlyFirstRunを0にする必要があります。

doInit

-- 好きな時間を登録する。いくつでもOK
«event MBASHndl» {|DoAtTime|:{|Handler|:"Hoge", |Time|:{|Hour|:8, |Minute|:0, |Second|:0}, |Repeat|:1, |DoOnlyFirstRun|:1}}
«event MBASHndl» {|DoAtTime|:{|Handler|:"Hoge", |Time|:{|Hour|:13, |Minute|:30, |Second|:0}, |Repeat|:1, |DoOnlyFirstRun|:1}}
«event MBASHndl» {|DoAtTime|:{|Handler|:"Hoge", |Time|:{|Hour|:19, |Minute|:0, |Second|:0}, |Repeat|:1, |DoOnlyFirstRun|:1}}

ハンドラ

on doAtTimeHoge(theFireTimeDifference, theIsWake, theIsFirstRun, theSettingRecord, theActiveAppRecord, theThisAppRecord)
	-- «event DebugLog» {"doAtTimeHoge", theFireTimeDifference, theIsWake, theIsFirstRun}
	
	-- 処理でネットワークに接続する場合、スリープ解除直後は
	-- ネットワークに繋がっていない場合があるので
	-- 下記のようにして10秒程度後に実行させると確実に繋がると思います。
	if theIsWake is 1 
		-- 起きた直後は10秒後に実行
		«event MBASHndl» {|DoAfterSec|:{|Handler|:"Hoge", |Sec|:10}}
	else
		-- 上の10秒待ちの間に指定時間が更に来た場合にハンドラを
		-- 直接実行しないでDoAfterSecですぐに実行するようにしておくと
		-- 10秒のはキャンセルされて0.01秒後に実行される。
		«event MBASHndl» {|DoAfterSec|:{|Handler|:"Hoge", |Sec|:0.01}}
	end if
	
	-- ネットに繋がない場合は上のようなめんどくさいことはしなくて
	-- したいことを直接書いてOK
	-- my hoge() 

end doAtTimeHoge

on doAfterSecHoge(theUserInfo, theActiveAppRecord, theThisAppRecord)
	-- スリープから復帰時の遅延実行用
	
	my hoge() -- したいこと
	
end doAfterSecHoge

DoAtTimeで指定時間にハンドラを実行する：手動繰り返し

DoAtTimeのサンプルです。

スリープから復帰時がややこしいですが、下記サンプルで細かいところまで対処できていると思います。動作テストはしてませんが…。

doInit

-- 好きな時間を登録する。いくつでもOK
«event MBASHndl» {|DoAtTime|:{|Handler|:"Hoge", |Time|:{|Hour|:8, |Minute|:0, |Second|:0}}}
«event MBASHndl» {|DoAtTime|:{|Handler|:"Hoge", |Time|:{|Hour|:13, |Minute|:30, |Second|:0}}}
«event MBASHndl» {|DoAtTime|:{|Handler|:"Hoge", |Time|:{|Hour|:19, |Minute|:0, |Second|:0}}}

ハンドラ

on doAtTimeHoge(theFireTimeDifference, theIsWake, theIsFirstRun, theSettingRecord, theActiveAppRecord, theThisAppRecord)
	-- «event DebugLog» {"doAtTimeHoge", theFireTimeDifference, theIsWake, theIsFirstRun}
	
	-- 繰り返すので再登録
	«event MBASHndl» {|DoAtTime|:theSettingRecord}
	
	-- 同じハンドラでDoAtTimeをいくつか登録した時にスリープして、
	-- 指定時間をいくつか過ぎた場合、
	-- スリープから起きた時に全部ハンドラが実行されるが1回だけ処理したい場合は
	-- 下記のように調べる。
	-- 起きている時に実行される時もtheIsFirstRunは1なので実行される。
	if theIsFirstRun is 1 then
		-- 処理でネットワークに接続する場合、スリープ解除直後は
		-- ネットワークに繋がっていない場合があるので
		-- 下記のようにして10秒程度後に実行させると確実に繋がると思います。
		if theIsWake is 1 
			-- 起きた時10秒後に実行
			«event MBASHndl» {|DoAfterSec|:{|Handler|:"Hoge", |Sec|:10}}
		else
			-- 上の10秒待ちの間に指定時間が更に来た場合にハンドラを
			-- 直接実行しないでDoAfterSecですぐに実行するようにしておくと
			-- 10秒のはキャンセルされて0.01秒後に実行される。
			«event MBASHndl» {|DoAfterSec|:{|Handler|:"Hoge", |Sec|:0.01}}
		end if
		
		-- ネットに繋がない場合は上のようなめんどくさいことはしなくて
		-- したいことを直接書いてOK
		-- my hoge() 

	end if
	
end doAtTimeHoge

on doAfterSecHoge(theUserInfo, theActiveAppRecord, theThisAppRecord)
	-- スリープから復帰時の遅延実行用
	
	my hoge() -- したいこと
	
end doAfterSecHoge

HTMLで作成した画像をメニューバーアイコンに設定する

アプリケーションアイコンの上に文字を重ねた画像をメニューバーアイコンにしたいと思ったのでやってみました。

下で使っているIconMaker.htmlの例：IconMaker.html

IconMaker.htmlを好きなように変更してMenuBarAppleScriptアプリケーション内部のResourcesフォルダに入れて下さい。

property

property theMenuBarItemImage : "mbas:icon" -- MenuBarAppleScript内部に保存するアイコン画像の名前。"mbas:"から始める必要があります。

doInit

-- "IconMaker.html"で表示した内容をアイコンにする
set theHTMLPath to (|resourcesFolderPath| of theThisAppRecord) & "IconMaker.html"
«event MBASHndl» {|WebViewWindow|:{|Name|:"IconMaker", |URL|:theHTMLPath, |Visible|:0, |DrawsBackground|:0}}

doInitで返すレコードの値

画像のみを表示する場合に必要

{|PriorityToMenuBarItemImage|:1}

ハンドラ

on doDidFinishLoadForFrame(theWindowName, theActiveAppRecord, theThisAppRecord)
	if theWindowName is "IconMaker" then
		-- 画像でMenuBarAppleScript内部に保存
		«event SW2PsPDF» {theMenuBarItemImage, "screen", "", theWindowName} 
		-- 保存した画像をメニューバーアイコンに設定して、ウインドウを削除
		«event MBASHndl» {|RemoveMenuBarItem|:1, |MenuBarItemImage|:theMenuBarItemImage, |WebViewWindow|:{|Name|:theWindowName, |Delete|:1}}
	end if
end doDidFinishLoadForFrame

アプリケーションにホットキー（ショートカットキー）を付ける

doInit

on doInit(theActiveAppRecord, theThisAppRecord)
	-- キーは小文字で指定する。shift + キーの場合、大文字で指定する。
	-- 修飾キー無しもできます
	return {|AppHotKeyList|:{{|Name|:"Save", |KeyChar|:"s", |ModifierKeyList|:{"command"}, |Enable|:1}, {|Name|:"Close", |KeyChar|:"w", |ModifierKeyList|:{"command"}, |Enable|:1}}}
end doInit

ハンドラ

on doAppHotKeySave(theActiveAppRecord, theThisAppRecord)
	-- 何か保存する処理
end doAppHotKeySave

on doAppHotKeyClose(theActiveAppRecord, theThisAppRecord)
	my hideWindow(theActiveAppRecord, theThisAppRecord)
end doAppHotKeyClose

scrollWheelMenuBarItemの使用例

この機能は1.3.1で無効になっています。

ハンドラ

on doScrollWheelMenuBarItem(theDeltaX, theDeltaY, theActiveAppRecord, theThisAppRecord)
	-- トラックパッドでスクロールした時にはイベントがたくさん来る
	-- イベントが終わったと思われるときに一回だけ実行するにはDoAfterSecで遅延実行を使うと簡単にできる
	--«event DebugLog» {"doScrollWheelMenuBarItem", theDeltaX, theDeltaY}
	-- Deltaは上、左が正の数、下、右が負の数	
	-- 遅延時間が多いと反応が遅くなるので適切な値に調整して下さい
	return {|DoAfterSec|:{|Handler|:"ScrollWheel", |Sec|:0.35, |UserInfo|:{theDeltaX, theDeltaY}}}
end doScrollWheelMenuBarItem

on doAfterSecScrollWheel(theUserInfo, theActiveAppRecord, theThisAppRecord)
	set theDeltaX to item 1 of theUserInfo
	set theDeltaY to item 2 of theUserInfo
	--«event DebugLog» {"doAfterSecScrollWheel", theDeltaX, theDeltaY}
	if theDeltaY ≥ 1 then
		-- 上
		say "up"
	else if theDeltaY ≤ -1 then
		-- 下
		say "down"
	else if theDeltaX ≥ 1 then
		-- 左
		say "left"
	else if theDeltaX ≤ -1 then
		-- 右
		say "right"
	end if
end doAfterSecScrollWheel

doHTTPResponseの使用例

フォルダ内のファイル一覧を返す例

ハンドラ

on startHTTPServer(theActiveAppRecord, theThisAppRecord)
	set theResult to «event HTTPSevr» {"start", {|Port|:50208, |DocumentRoot|:"~/", |DirectoryIndexFileNames|:{}, |User|:"", |Password|:""}}
	if theResult is not 1 then
		activate
		beep
		display alert "サーバーの起動に失敗しました。アプリケーションを終了します。" & return & theResult
		«event MBASHndl» {|Quit|:1}
	end if
	
	-- set theThisAppRecord to «event InfoTApp»
	-- do shell script "open " & quoted form of HTTPServerURL of theThisAppRecord
end startHTTPServer

on doHTTPResponse(theRequestPath, theDocumentFilePath, theMethod, theActiveAppRecord, theThisAppRecord)
	«event DebugLog» {theRequestPath, theDocumentFilePath, theMethod}
	
	if theDocumentFilePath ends with "/" then
		if theRequestPath does not end with "/" then
			set theRequestPath to theRequestPath & "/"
		end if
		
		-- パスに '' が含まれていると駄目です
		
		set theTemplate to "
	<html>
	<head>
	<title>{{ folder | html }}</title>
	</head>
	<body>

	<h1>{{ folder | html }}</h1>
	<a href='{{ parentFolder | html }}'>UP</a>
	<ol>
	{% for path in paths %}
	<li><a href='{{ parentPath }}{{ path }}'>{{ path | html }}</a></li>
	{% /for %}
	</ol>
	</body>
	</html>
"
		
		set theParentFolderPath to «event TextPath» {"stringByDeletingLastPathComponent", theRequestPath}
		
		set theList to «event TextPath» {"contentsOfDirectory", theDocumentFilePath, {"SkipsHiddenFiles", "AddSlashToFolder"}}
		
		if theRequestPath is "/" then
			set theParentPath to ""
		else
			set theParentPath to theRequestPath
		end if
		
		set theValue to {|folder|:theDocumentFilePath, |parentPath|:theParentPath, paths:theList, |parentFolder|:theParentFolderPath}
		set theHTML to «event TextUtil» {"MGTemplateEngine", theTemplate, theValue}
		
		return {|HTTPResponse|:{|HTML|:theHTML, cache:0}}
	else
		return {|HTTPResponse|:{|File|:theDocumentFilePath}}
	end if
end doHTTPResponse

MGTemplateEngineのテンプレート例

-- リスト
set theTemplate to "
	<h1>{{ title | html }}</h1>
	<p>{{ note | html }}</p>
	<ol>
	{% for item in items %}
		<li>{{ item | html }}</li>
	{% /for %}
	</ol>
"

set theTitle to "<リストのサンプル>"
set theNote to "リストをHTMLのリストに変換"

set theItemList to {}
set end of theItemList to "黒"
set end of theItemList to "猫"
set end of theItemList to "白"
set end of theItemList to "犬"

set theValueRecord to {|items|:theItemList, title:theTitle, |note|:theNote}

set theHTML to «event TextUtil» {"MGTemplateEngine", theTemplate, theValueRecord, {}, {|OpenHTML|:0, |Browser|:"Safari", |OpenText|:0, |Editor|:"mi", |Activate|:0, |Name|:"Test"}}


-- レコード
set theTemplate to "
	<h1>{{ title | html }}</h1>
	<p>{{ note | html }}</p>
	<table>
		<tr>
			<th>{{ label.Name | html }}</th>
			<th>{{ label.Kind | html }}</th>
			<th>{{ label.Age }}</th>
		</tr>
	{% for item in items %}
		<tr>
			<td>{{ item.Name | html }}</td>
			<td>{{ item.Kind | html }}</td>
			<td>{{ item.Age }}</td>
		</tr>
	{% /for %}
	</table>
"

set theTitle to "<テーブルのサンプル>"
set theNote to "レコードのリストをテーブルに変換。キーに'name'を使用したらMGTemplateEngineのキーワードのようで表示されませんでした。その為'Name'にしました。"

set theLabel to {|Name|:"名前", |Kind|:"種類", Age:"年齢"}

set theItemList to {}
set end of theItemList to {|Name|:"ミケ", |Kind|:"ねこ", Age:10}
set end of theItemList to {|Name|:"ポチ", |Kind|:"イヌ", Age:2}
set end of theItemList to {|Name|:"たまちゃん", |Kind|:"あざらし", Age:7}
set end of theItemList to {|Name|:"マイケル", |Kind|:"ねこ", Age:15}

set theValueRecord to {|items|:theItemList, label:theLabel, title:theTitle, |note|:theNote}

set theHTML to «event TextUtil» {"MGTemplateEngine", theTemplate, theValueRecord, {}, {|OpenHTML|:0, |Browser|:"Safari", |OpenText|:0, |Editor|:"mi", |Activate|:0, |Name|:"Test"}}

新しいバージョンのアプリケーションがリリースされているかチェックする

property

-- バージョンチェックの間隔
property theAppVersionCheckIntervalSec : days * 7
-- バージョン情報が記載されたJSONのURL
property theAppVersionJSONURL : "https://googledrive.com/host/0B7jmDxmCrfK0UUJub1p6NnAxcGc/version.js"

doInitで返すレコードの値

|VersionCheck|:{|URL|:theAppVersionJSONURL, |Interval|:theAppVersionCheckIntervalSec}},

バージョンを記載したJSONを作るAppleScript

theAppVersionJSONURLで参照するファイルを作るAppleScriptです。

MenuBarAppleScriptの機能で作っています。

ファイルの書き出しにdo shell scriptを使ったら、エスケープされた改行が解除されて動かなくなったので、AppleScriptの命令を使用しています。

commentはdisplay dialogでそのまま表示されます。改行したい場合はreturnでつないで下さい。

property theHistoryJSPath : "/Users/hage/Sites/foo/version.js"

tell application "MenuBarAppleScript"
	«event DictDelV» {"tmp", "version"}
	
	-- ここにアプリケーション名とバージョン、URL、コメントを書いていく
	«event DictDict» {"tmp", "version", "setObjectForKey", {|version|:"1.4.1", |url|:"http://memogakisouko.appspot.com/MenuBarAppleScript.html", comment:"・いろいろ機能を追加"}, "MenuBarAppleScript"}
	
	«event DictDict» {"tmp", "version", "setObjectForKey", {|version|:"1.4.1", |url|:"http://memogakisouko.appspot.com/MenuBarAppleScript.html#AppleScriptEditorHelper", comment:"・MenuBarAppleScript1.4.1の用語に対応"}, "AppleScriptEditorHelper"}
	
	set theValue to «event DictGetV» {"tmp", "version"}
	
	set theJSONText to «event TextUtil» {"writeJSON", theValue}
	«event TextUtil» {"writeToFile", theHistoryJSPath, theJSONText}
	quit
end tell

指定時間、スリープ復帰時になどを考慮した一定間隔で処理をするサンプル

-- 指定時間、スリープ復帰時、一定時間間隔に処理をする -- いくつかハンドラがありますが処理自体はdoIdleで行いますのでdoIdleにしたい処理を書きます property theUpdateIntervalSec : hours * 2.0 -- 更新間隔。この秒数間隔で処理を定期的に実行 on doInit(theActiveAppRecord, theThisAppRecord) -- 例：0時5分に日が変わった時の処理をする «event MBASHndl» {|DoAtTime|:{|Handler|:"NextDay", |Time|:{|Hour|:0, |Minute|:5, |Second|:0}, |Repeat|:1, |DoOnlyFirstRun|:0}} -- idleとdidWakeを登録 return {|IdleSec|:theUpdateIntervalSec, |NSWorkspaceNotificationList|:{"NSWorkspaceDidWakeNotification"}} end doInit on doNSWorkspaceDidWakeNotification(theNotificationName, theObject, theUserInfo, theActiveAppRecord, theThisAppRecord) -- «event DebugLog» "NSWorkspaceDidWakeNotification" -- スリープから復帰後に更新したいけどwifi再接続に時間がかかる場合あるのでちょっと後に更新 -- IdleSecは上書き可能なのでこれでOK return {|IdleSec|:20} end doNSWorkspaceDidWakeNotification on doAtTimeNextDay(theFireTimeDifference, theIsWake, theIsFirstRun, theSettingRecord, theActiveAppRecord, theThisAppRecord) «event DebugLog» {"doAtTimeHoge", theFireTimeDifference, theIsWake, theIsFirstRun} if theIsWake is 1 then -- wake時はdidWakeで処理しているので何もしない else -- 直接実行しないでこれでdoIdleを呼ぶようにすると、 -- 通常のdoIdleやNSWorkspaceDidWakeNotificationがほぼ同時に実行される場合に -- それらをキャンセルして一回だけ実行されるようにできる。 return {|IdleSec|:20} -- チャイムを時間ピッタリに鳴らすなどの場合はここで直接実行するか0.01を返すなどにして下さい end if end doAtTimeNextDay on doIdle(theActiveAppRecord, theThisAppRecord) -- ここで一定間隔＆ほぼ指定時間＆スリープ復帰時にしたい処理を実行 my hoge() return {|IdleSec|:theUpdateIntervalSec} end doIdle

メモ

• plistの"Scriptable"をONにするとAppleScript エディタで開いた時に用語説明が表示されるのでONにしてはいけない。

デバッグ方法

基本

• 最初にスクリプトを書く時の注意点は一度は見ておいて下さい。
• { |DebugLog|:1, |LogAppleScriptError|:1 }を返します。
• スクリプトのエラーがコンソールに出力されるようになります。
• 変数の値を表示したい場合は«event DebugLog» theValueを実行するとコンソールに表示されます。注意点は表示できるのは数値とテキストのみでエイリアスやアプリケーション独自の値等は表示できません。
• スクリプト中で使う値をpropertyじゃなくて辞書(ハッシュ)関係の命令で保存するとスクリプトを変更して、保存した時に値が初期化されないので、アプリケーションの状態を保ったまま、スクリプトの修正ができます。初期化は一度しかされないのでdoInitで返す値を変更した場合はアプリケーションを再起動する必要があります。また、辞書の値を保存する様にしておけば、強制終了じゃない限り、アプリケーションを終了、再起動した時も値を保持できます。
• スクリプトでエラーが起きた後にスクリプトを修正したのに何故か動かないな、って時は、書いているアプリケーションを再起動する必要がある場合があります。

AppleScriptエディタで実行してイベントログを確認する方法

通常のスクリプト同じようにイベントログを確認しながらデバッグするには次のようにします。

下記画像の設定をオンにします

MenuBarAppleScriptの名前等の初期設定をすると自動的にアプリケーションがライブラリに登録されるので登録されているか確認します。未登録の場合は、MenuBarAppleScriptが最新バージョンか確認して、再設定して下さい。

デバッグしたいスクリプトを下記スクリーンショットの様にします。このメニューにアプリケーションが表示されない場合は、一つ前のステップに戻って下さい。

ここまでで設定完了であとは実行すればMenuBarAppleScriptの機能を使ったり、実行中のアプリケーションの状態を取得、設定できるようになります。

10.8では実行時に下記ダイアログが表示されますが、「スクリプトを実行」を押して下さい。

実行した時のスクリーンショット

Tips

• スクリプトを書く時の注意点は一度は見ておいて下さい。

FAQ - スクリプトを書く時の注意点

• イベントが起きた時に実行されるハンドラ(doSelectMenuItemなど)はハンドラが見つからなかった場合、2回目以降は実行されません。また、実行されなくなった後にハンドラを追加しても実行されません。アプリケーションに少しずつハンドラを追加して開発している場合、この現象で追加したイベントのハンドラが実行されない場合がありますので気をつけて下さい。
• スクリプトでエラーが起きた後にスクリプトを修正したのに何故か動かないな、って時は、書いているアプリケーションを再起動する必要がある場合があります。
• ハンドラで返す値のレーコードの通知名は大文字小文字も含めて正確に書く必要があります。大文字小文字を区別しないのも多いです。
• レコードのキーは|key|と書くようにした方が安定します。スペースが無い場合はkeyでも書けるのですが、大文字小文字を最初に間違った時に、修正しても自動的に前の値に戻されたりする場合があり、なんで動かないんだろうと、はまることがあります。コピー＆ペーストした時に|key|が| key |のようにスペースが入っていないも注意して下さい。最新版ではそういうことが多かったので大文字小文字を区別しないのでここではまることはなくなっています。
• リストで返すところをリストじゃない通常の値で返すと動きませんので注意して下さい。すべての処理で値チェックはしませんので注意して下さい。
• ハンドラで返すレーコードでは文字列と数値だけを含むようにして下さい。文字列と数値以外を含むとレコード全体を認識できなくなります。true、falseは使えません。true,falseに該当する値の場合は1,0を返して下さい。アプリケーション独自の値なども駄目です。

• repeat with theStr in theStrList
  	-- ☆要注意
  	-- この参照の theStr を含むリスト { theStr }をMenuBarAppleScriptに渡すと処理が行われない場合があります。
  	-- エラーも何もでないのでバグに気がつきにくいです
  	-- そのようなケースにであったら contents of theStr か theStr as text などして下さい。
  end repeat
  

• OnLoadJavaScriptは読み込み完了時に実行されます。URLやHTMLを未指定でOnLoadJavaScriptを設定してもOnLoadJavaScriptは実行されません。|JavaScript|もしくは«event WebVJS__»を使って下さい。
• OnLoadJavaScriptが実行されない場合は実行するJavaScriptで値を返すようにしてみて下さい。最後に"1;"を付け足すなど。
• システム終了時、再起動時のdoQuitでdelayを使うと、スクリプト実行中でもアプリケーションが終了してしまう場合があります。
• 起動時のイベントハンドラの実行順は、doInit、doRun、サービス関連です。
• UI Elementで取得できるRangeのposは0ベースです。UI Elementで指定するときも0ベースです。AppleScriptで文字を指定するときは1ベースになりますので、1を足したり、引いたりする必要があります。
• Mac OS X 10.8.2 の Evernote 5.0.5でAXNotificationListにAXSelectedTextChangedを設定してもAXWebAreaのAXSelectedTextChangedの通知が来ない場合があります。その場合は、次のようなハンドラを作って事前に実行すると通知がすぐに来るようになりました。

  on touchAXWebArea()
  	if 0 is not («event UIElSetE» {"Evernote", {"Attr", "AXFocusedWindow", "AnyRole", "(AXSplitGroup|AXGroup|AXScrollArea|AXTabGroup)", "AXRole", "AXWebArea"}}) then
  		«event UIElGetV» {"AXValue"} -- 10.8.2では一度AXWebAreaを触らないとdoAXSelectedTextChangedがなかなか来ない
  		--«event DebugLog» "ax test"
  	end if
  end touchAXWebArea
  

• «event SW2PsPDF»でdivなどにbackground-colorを付けてレイアウトしたものを画像にした時に真っ白になる場合は"printbackgrounds"を指定して下さい。
• doWindowWillCloseでウインドウを削除してもウインドウが通知自体で保持されているためdoWindowWillCloseのハンドラが終了するまでウインドウが削除されません。実行中にウインドウが表示されていて別のウインドウの表示に影響が出る場合は、
  «event MBASHndl» {|WebViewWindow|:{|Name|:theWillCloseWindowName, |Visible|:0}}
  でウインドウを隠しておいて下さい。Deleteを実行するとその他の処理が一切されないので|Visible|:0と|Delete|:1は別々に実行して下さい。

バグ

• WebViewWindowを表示すると!!! _NSLayoutTreeLineFragmentUsedRectForGlyphAtIndex invalid glyph index 0ってエラーがコンソールに出る場合がありますが、原因は不明です。
• AppleScriptでtell app "MenuBarAppleScript" to every windowを実行してもWebView Windowが取得できない(まれに取得できることもある)。System Eventでも同じ。
• AXNotificationの機能はアプリケーションを名前で指定するので同じ名前のアプリケーションが複数同時に起動していると期待通りに動かない場合があると思います。
• WebViewWindowのCanHideを設定してもウインドウが隠れません。
• doNSWorkspaceDidActivateApplicationNotificationでウインドウの表示を変更しているアプリケーションがたまにエラーで強制終了する場合がある。

今後する機能追加するかもしれないこと

• メニューバーに複数のアイテムを登録できたらいいかも、と思ったのでWebViewWindowのように名前を付ける感じでできるようにするかもしれません。

コメント

1.4.2

何故、他のスクリプト言語やアプリケーションやOSAX、そしてAppleScript自体でできる命令を追加しているのかというと、主に次の2つの理由です。

一つは配布する時に、他のソフトのインストール無しでMenuBarAppleScriptのアプリケーションをダブルクリックするだけでアプリケーションが動作してすぐに試せる方がいいんじゃないか、というのがあります。その為、OS標準のコマンドやアプリケーション以外はできるだけ使わなくて済むように命令を追加してます。

もう一つは複数行のAppleScriptのハンドラやスクリプト言語で書くことができるけど、それらを書くのが面倒くさいので1行で書ける命令を追加してしまおう、ってのがあります。正規表現を数百回実行する場合などは、スクリプト言語を数百回起動させるよりMenuBarAppleScriptの命令のほうが実行速度も早かったので、そういう利点もあるかな、と思ってます。

1.0.0

長年謎だった、AXWebAreaのAXSelectedTextMarkerRangeの使い方がついに分かったので、MenuBarAppleScriptで使えるようにしてみました。これで、クリップボードやサービスを使わずにSafari、Evernote、MailなどAXWebAreaを使ったアプリケーションの選択しているテキストを同じスクリプトで取得できます！。

0.7.2

細かい機能だけどあればスクリプトの作成が楽になるものをいくつか追加。

AXNotificationは奥が深いけど、Cocoaだとちょっと試すのも結構めんどくさいのが、AppleScriptで手軽にいろいろ挑戦できるのがいい感じです。非常にとっつきにくいけど、通常できなさそうなことができたりする場合があるのでお勧めです。

0.7.0

アプリケーションを作るのにあたって欲しいと思った機能を追加しています。しかし、そろそろ完成が近づいているのではないでしょうか。メニューバーアイテムを二つ以上作れないのが気になってますが、結構大きな変更になりそうだし、メニューバーのスペースの関係もあり、なかなか手を出せないでいます。

0.5.1

以前から気になっていたEventListの指定とdoInitでエラーが表示されないのを改善してみました。これで結構作りやすくなったと思います。

YouTubePlaylistPlayerを作ってて思いましたが、独自の命令がいっぱいでAppleScriptだけど通常のAppleScriptとは全く違う物になってしまった感じです。しかし、ハッシュ、リスト、正規表現の命令があると開発効率がいいですね。

0.5.0

非同期でUnixコマンドを実行する命令を付けました。コマンドが実行中でも出力を取得して処理をできるので、curlやffmpegの途中経過を表示するのに使えると思います。 osascriptでスクリプトを非同期で実行させて擬似的にスレッドを実現できそうですが、いろいろ考えても必要な場面が思いつかなかったので、使ったことはありません。

その他いろいろと欲しい機能を追加しました。

0.4.1

今まで、Property List Editorで設定していた、URLスキームを初期設定で指定できるようにしました。ブラウザのUserScriptからURLスキームを使ってMenuBarAppleScriptに命令を飛ばして、いろいろ処理したり、結果をAppleScriptでブラウザに反映させる、ってのをやってますが、結構面白いです。

0.4.0

正規表現とパス関係とURLエンコードなど、自分がスクリプト書く時にdo shell scriptのお世話になっている機能をいくつか入れてみました。正規表現でテストしたところではdo shell scriptでperlより«event TextRegx» の方が速かったです。

0.3.0

AppleScriptEditorHelperを作っててハッシュ機能が欲しくなったので、似たようなことができるようにしましたが、有る無しで開発効率が全然違いますね。

0.2.2

AXNotificationをとりあえず、アプリケーション全体で設定できるようにしてみました。なかなか面白いネタは思いつきませんが、サンプルで作ったmdlsViewerはいい感じで今後mdls、mediainfoで調べる時はこれを使うと思います。サービスメニューを選択したりドラッグドロップでファイルをアプリケーションに渡す手間がないのは楽でいいですね。

0.2.1

他の人が作ったMenuBarAppleScriptのスクリプトを見て、スクリプトのオーナというのか実行主がアプリケーション本体だというのを今頃知りました。それで«event MBASHndl»命令を追加してみました。何かと使えるのではないでしょうか。

0.1.0

いろいろとMenuBarAppleScriptのネタが思いついてAppleScript魂が久しぶりに燃えています！。作った後に実用するかどうかは分からないけど・・・。

思ったよりややこしいので作り方で分からないことがあったらご連絡ください。

AppleScriptEditorHelper

AppleScript エディタでAppleScriptを書くのを補助するアプリケーションです。$200のエディタを使ってる人には必要無いと思いますが、AppleScript エディタを使ってる自分が欲しい機能をいくつか入れてみました。

MenuBarAppleScriptの命令、キーワードを挿入できるのでMenuBarAppleScriptのスクリプトを書くには必須アイテムです。

「ユニバーサルアクセス」環境設定で「補助装置にアクセスできるようにする」にチェックを入れる必要があります。[設定のスクリーンショット]

UI Element関係の命令を使ったサンプルで何かネタが無いかと思っていたのですが、前から思っていたAppleScriptエディタの不便なところを結構解消できるアプリケーションができました。

使い方：メニューバーのAppleScript エディタのアイコンのメニューから操作します。ToolbarAppleScriptと同梱のスクリプトを使用するとウインドウのツールバーから手軽に操作できるようになります。

ASEverHelperとあわせて自分のAppleScript制作環境がかなり良くなった感じです。

機能

• 起動中のアプリケーションのtell app "hoge"、tell process "hage"をメニューから挿入できる。
• 起動中のアプリケーションをメニューから終了、終了＆起動できる
• 選択部分のテキストをコメント、アンコメントできる。
• ハンドラとプロパティへ移動できるジャンプメニュー。標準のジャンプメニューだと"　"の中に改行を書いたHTMLやスクリプト等があると、その下のハンドラが表示されないことがあったので。対応するハンドラの書き方はon hage( foo, bar )だけです。
• スクリプト中で定義したハンドラ、プロパティをメニューから挿入できる。
• 直前に表示していた、テキスト部分にスクロールできる、進む、戻る、機能。例えば、スクリプトの他の部分をちょっと変更したあと、今のところに戻るのが、戻るボタンを押すだけでできます。ウインドウ分割ができないので付けてみました。この機能のスクロール位置は行単位のテキストで覚えています。テキストを編集すると戻れなくなる場合があります。また、期待通りに戻れないときもあります。また、スクロール位置も期待している位置とちょっとズレていることが多いと思います。
• スクリプトを別ウインドウにクリップして表示する機能。ウインドウ分割ができないので付けてみました。
• MenuBarAppleScriptの命令やキーワードを挿入できる。
• 選択した変数名・ハンドラ名を置換できる。

ダウンロード

MBAS_AppleScriptEditorHelper1.4.5.zip

MenuBarAppleScript 1.4.5

MenuBarAppleScriptの命令挿入機能のキーワードを更新。

サンプル置き場

MenuBarAppleScriptで作ったアプリケーションに移動しました。

リンク

MenuBarAppleScriptで作られたアプリケーションや紹介記事

新しくメモした順

• ブックマークレットが実行できるMarkdownビューア『markdownlet』 - Macの手書き説明書
• ブログを書く時に便利な『Convert HTML Tag』を作り直しました - Macの手書き説明書
• Mac App Storeのアフィリエイトリンクを作成してクリップボードへコピー『MAS Helper』 - Macの手書き説明書
• 歌詞をフルスクリーンで表示して音楽に没頭できるiTunesコントローラ『Lyric Controller』 - Macの手書き説明書
• ひしょか王 - [Mac] 地上波ラジオをメニューバーから聴くアプリを作った
• ひしょか王 - [Mac] 指定したTumblrの画像をフルスクリーンかつランダムに表示するアプリを作った
• 青空文庫をカスタムCSSと指定した行で区切りフルスクリーンで読む『青空読書』 - Macの手書き説明書
• メニューバーに降水確率や予報などのお天気情報を表示『menubarTenki』 - Macの手書き説明書
• iTunesで再生中の曲の情報をメニューバーから常に確認でき、曲変更時に通知も表示する『menubarTunes』 - Macの手書き説明書
• 選択した文章を句読点などで区切りスライドショーのように読む『fullscreen text slideshow』をさらに改良しました - Macの手書き説明書
• アクティブなWebブラウザで開いているサイトを他のWebブラウザで開き直す『Send URL to WebBrowser』 - Macの手書き説明書
• AppleScriptの知識だけでメニューバーアプリを作ることができる『MenuBarAppleScript』 - Macの手書き説明書

ダウンロード

MenuBarAppleScript2.0.0

«event RemvEvnt» {"TextPath", "TextUtil", "Cmd_Run_"}を追加。MenuBarAppleScriptの命令を実行できなくできます

ユーザー登録の認証ができるcocoafobを組み込みました。
«event ChckRegi»{theLicenseName, theLicenseKey}を追加

RequireRegistraionMenuItemListなどを追加。ユーザー登録されているかどうかでメニュー項目を自動的に変更できます。

メニューアイテムに"---hide registered"か"---hide notregistered"を追加。ユーザー登録されているかどうかでメニュー項目を自動的に表示するか、隠すかできます。

LetsMoveを組み込みました

«event ASBMExec»{theVal1, theVal2}を追加

ASBMExecLoopを追加

SCNotificationIgnoreKeyListを追加

«event PostSKey»を追加

«event PostDNti»を追加

KanaEisuuKeyDownSpaceIsNormalCharを追加

10.6.8でアプリケーションに直接送れなくなっていた«event PostKeyE»のバグを修正。

«event HndlList» {theList,"insertListAfterEveryItem", theInserList }を追加

«event HndlList» {theList,"insertListBeforeEveryItem", theInserList }を追加

«event HndlList» {theList,"insertListAfterTheItem", "find", theInserList }を追加

«event HndlList» {theList,"insertListBeforeTheItem", "find", theInserList }を追加

«event DictList» {dictName,listKey,"insertListAfterEveryItem", theInserList }を追加

«event DictList» {dictName,listKey,"insertListBeforeEveryItem", theInserList }を追加

«event DictList» {dictName,listKey,"insertListAfterTheItem", "find", theInserList }を追加

«event DictList» {dictName,listKey,"insertListBeforeTheItem", "find", theInserList }を追加

使ってない機能は(ほとんど、もしくはぜんぜん)テストしてないのでおかしいと思ったら、ご連絡ください。使い方が分からない場合もどうぞ。

AppleScriptEditorHelperにMenuBarAppleScriptの命令、キーワード挿入機能があるので、MenuBarAppleScriptのスクリプトを書く時にお勧めです。自分はこれが無いと書けません。最新版はMenuBarAppleScript1.4.6に対応しています。

MenuBarAppleScript1.4.5

MenuBarAppleScript1.4.5.zip

10.9で「MenuBarAppleScript初期設定.app」で初期化する時にエラーになって初期設定できない問題を修正

初期設定スクリプトの修正のみで本体に機能追加はありません。

使ってない機能は(ほとんど、もしくはぜんぜん)テストしてないのでおかしいと思ったら、ご連絡ください。使い方が分からない場合もどうぞ。

AppleScriptEditorHelperにMenuBarAppleScriptの命令、キーワード挿入機能があるので、MenuBarAppleScriptのスクリプトを書く時にお勧めです。自分はこれが無いと書けません。最新版はMenuBarAppleScript1.4.5に対応しています。

MenuBarAppleScript1.4.4

MenuBarAppleScript1.4.4.zip

サーバー機能でアプリケーションが落ちる場合があるのをちょっと対処

カラーピッカーでグレースケールでカラーを選んだ時にエラーになる問題を修正

10.7以降のサンドボックス対応アプリケーションでは«event PostKeyE»で指定したアプリケーションに直接キーイベントを送れないので指定したアプリケーションをアクティブにして、システムに対してキーイベントを送るようにした。

10.9のタグを取得、設定できる命令を追加。«event TextPath» {"getTag", thePath }以降を参照。

スポットライトコメントに書いたタグを10.9のタグに設定するアプリケーションSpotlightCommentToMavericksTagも参考にしてみて下さい。

使ってない機能は(ほとんど、もしくはぜんぜん)テストしてないのでおかしいと思ったら、ご連絡ください。使い方が分からない場合もどうぞ。

AppleScriptEditorHelperにMenuBarAppleScriptの命令、キーワード挿入機能があるので、MenuBarAppleScriptのスクリプトを書く時にお勧めです。自分はこれが無いと書けません。最新版はMenuBarAppleScript1.4.4に対応しています。